ConsoleTuner

Can this script be converted to T2?

GPC2 script programming for Titan Two. Code examples, questions, requests.
Post a reply

Can this script be converted to T2?

Postby fdg0d » Fri Dec 07, 2018 8:06 pm

Can this be converted to T2?

CEMU_EXTRA2 = V
CEMU_EXTRA3 = G
CEMU_EXTRA4 = 5
CEMU_EXTRA5 = 9
CEMU_EXTRA6 = E
CEMU_EXTRA8 = O
CEMU_EXTRA9 = L

Code: Select all
define A_Button = PS4_CROSS;
define Right_Trigger = PS4_R2;
define Left_Stick_Down = PS4_L3;
define Right_Stick_Down = PS4_R3;
 
define D_Pad_Up = PS4_UP;
define D_Pad_Right = PS4_RIGHT;
define D_Pad_Down = PS4_DOWN;
define D_Pad_Left = PS4_LEFT;
 
define LeftStick_Left_Right = PS4_LX;
 
/* Rumble packs */
define Rumble_Right = RUMBLE_B;
 
 
int disable_touchpad = 101;
 
int OpeningLock = FALSE;
int Max_Rumble = 75;
int TumblersToOpen;
 
 
int Toggle = FALSE;
int LLockpick = FALSE;
 
 
 
 
main {  
 
 
 
     if(event_press(CEMU_EXTRA2)){
        Toggle=!Toggle;
    }
    if(Toggle){
 
        swap(PS4_CIRCLE, PS4_DOWN);
    swap(PS4_CROSS, PS4_R3);
    }
 
 
 
    if(event_press(CEMU_EXTRA9)){
        combo_run(InitOpenChestScript);
    }
    if(OpeningLock && event_press(PS4_CROSS)){
        combo_run(ResetAll);
    }
 
    //Lockpicking scripts
    if(OpeningLock){
        set_val(Right_Trigger, 100);
    }
    if(get_rumble(Rumble_Right) > Max_Rumble && OpeningLock && TumblersToOpen > 0){
        combo_run(OpenChestScript);
    }
 
 
 
 
 
   if(event_press(CEMU_EXTRA3)) {
        combo_run(Synergy);
     }
 
    if(event_press(CEMU_EXTRA4)) {
        combo_run(Ultimate);
     }
 
     if(event_press(CEMU_EXTRA6)) {
        combo_run(Bash);
 
     }
 
     if((get_val(PS4_L2)) && (get_val(PS4_L3))) {
        combo_run(Dodge);
    }
 
    if(get_val(CEMU_EXTRA5)) {
        combo_run(Rotation);
        }
 
    else if(combo_running(Rotation)) combo_stop(Rotation);
 
     if(get_val(CEMU_EXTRA8)) {
        Toggle = FALSE;
 
     }
 
 
 
 
 
 
 
 
 
    set_val(PS4_TOUCHX, disable_touchpad);
    set_val(PS4_TOUCHY, disable_touchpad);
 
 
}
 
 
 
combo Synergy {
    set_val(PS4_CIRCLE, 100);
    wait(90);
    set_val(PS4_TRIANGLE, 100);
    set_val(PS4_CIRCLE, 100);
    wait(90);
    set_val(PS4_TRIANGLE, 100);
    set_val(PS4_CIRCLE, 0);
    wait(20);
    set_val(PS4_TRIANGLE, 0);
}
 
combo Ultimate {
    set_val(PS4_L1, 100);
    wait(90);
    set_val(PS4_R1, 100);
    set_val(PS4_L1, 100);
    wait(90);
    set_val(PS4_R1, 100);
    set_val(PS4_L1, 0);
    wait(20);
    set_val(PS4_R1, 0);
}
 
combo Bash {
    set_val(PS4_R2, 0);
    set_val(PS4_L2, 100);
    wait(90);
    set_val(PS4_R2, 100);
    set_val(PS4_L2, 100);
    wait(90);
    set_val(PS4_R2, 100);
    set_val(PS4_L2, 0);
    wait(20);
    set_val(PS4_R2, 0);
}
 
combo Lockpick {
    set_val(PS4_R2, 0);
    wait(100);
}
 
combo Dodge {
    set_val(PS4_L2, 100);
    wait(50);
    set_val(PS4_L2, 100);
    set_val(PS4_CROSS, 100);
    wait(100);
    set_val(PS4_L2, 100);
    set_val(PS4_CROSS, 0);
    wait(30);
    set_val(PS4_L2, 0);
}
 
combo Rotation {
 
    set_val(PS4_R2, 100);
    wait(100);
    set_val(PS4_R2, 0);
    wait(100);
    set_val(PS4_R1, 100);
    wait(100);
    set_val(PS4_R1, 0);
    wait(1000);
    set_val(PS4_R2, 100);
    wait(100);
    set_val(PS4_R2, 0);
    wait(100);
    set_val(PS4_L1, 100);
    wait(100);
    set_val(PS4_L1, 0);
    wait(2000);
 
 
}
 
 
 
 
 
 
 
combo InitOpenChestScript
{
    //Wait for lock to load then move to far left tumbler.
    set_val(A_Button, 100);
    wait(200);
    set_val(A_Button, 0);
    wait(600);
    set_val(LeftStick_Left_Right, -100);
    wait(400);
    set_val(LeftStick_Left_Right, 0);
    TumblersToOpen = 5;
    OpeningLock = TRUE;
}
 
combo OpenChestScript
{
    //Stop right trigger press and move to next tumbler.
    set_val(Right_Trigger, 0);
    set_val(LeftStick_Left_Right, 100);
    wait(200);
    set_val(LeftStick_Left_Right, 0);
    TumblersToOpen = TumblersToOpen - 1;
    if(TumblersToOpen <= 0){OpeningLock = FALSE;}//Once all pins are depressed turn off the script
}
 
combo ResetAll
{
    set_val(A_Button, 0);
    set_val(Right_Trigger, 0);
    set_val(Left_Stick_Down, 0);
    set_val(Right_Stick_Down, 0);
 
    set_val(D_Pad_Up , 0);
    set_val(D_Pad_Right, 0);
    set_val(D_Pad_Down, 0);
    set_val(D_Pad_Left, 0);
    set_val(A_Button, 0);
 
    OpeningLock = FALSE;
}
 
 
 
 
 
 
 
 
User avatar
fdg0d
Sergeant Major
Sergeant Major
 
Posts: 83
Joined: Thu May 12, 2016 3:16 pm
Top

Re: Can this script be converted to T2?

Postby J2Kbr » Sat Dec 08, 2018 8:15 am

Converted to Titan Two native code.
Code: Select all
#include <keyboard.gph>
#include <ps4.gph>
 
#define A_Button                PS4_CROSS
#define Right_Trigger           PS4_R2
#define Left_Stick_Down         PS4_L3
#define Right_Stick_Down        PS4_R3
 
#define D_Pad_Up                PS4_UP
#define D_Pad_Right             PS4_RIGHT
#define D_Pad_Down              PS4_DOWN
#define D_Pad_Left              PS4_LEFT
 
#define LeftStick_Left_Right    PS4_LX
 
/* Rumble packs */
#define Rumble_Right            FFB_2
 
bool OpeningLock = FALSE;
fix32 Max_Rumble = 75.0;
int TumblersToOpen;
 
bool Toggle = FALSE;
bool LLockpick = FALSE;
 
bool CEMU_EXTRA2, CEMU_EXTRA9, CEMU_EXTRA3, CEMU_EXTRA4, CEMU_EXTRA6;
 
main {  
    if(key_status(KEY_V)){
        if(!CEMU_EXTRA2) {
            CEMU_EXTRA2 = TRUE;
            Toggle = !Toggle;
        }
    } else CEMU_EXTRA2 = FALSE;
    if(Toggle){
        swap(PS4_CIRCLE, PS4_DOWN);
        swap(PS4_CROSS, PS4_R3);
    }
 
    if(key_status(KEY_L)){
        if(!CEMU_EXTRA9) {
            CEMU_EXTRA9 = TRUE;
            combo_run(InitOpenChestScript);
        }
    } else CEMU_EXTRA9 = FALSE;
    if(OpeningLock && event_active(PS4_CROSS)){
        combo_run(ResetAll);
    }
 
    //Lockpicking scripts
    if(OpeningLock){
        set_val(Right_Trigger, 100.0);
    }
    if(ffb_get(Rumble_Right, NULL) > Max_Rumble && OpeningLock && TumblersToOpen > 0){
        combo_run(OpenChestScript);
    }
 
    if(key_status(KEY_G)) {
        if(!CEMU_EXTRA3) {
            CEMU_EXTRA3 = TRUE;
            combo_run(Synergy);
        }
    } else CEMU_EXTRA3 = FALSE;
 
    if(key_status(KEY_5)) {
        if(!CEMU_EXTRA4) {
            CEMU_EXTRA4 = TRUE;
            combo_run(Ultimate);
        }
    } else CEMU_EXTRA4 = FALSE;
 
    if(key_status(KEY_E)) {
        if(!CEMU_EXTRA6) {
            CEMU_EXTRA6 = TRUE;
            combo_run(Bash);
        }
    } else CEMU_EXTRA6 = FALSE;
 
    if(get_val(PS4_L2) && get_val(PS4_L3)) {
        combo_run(Dodge);
    }
 
    if(key_status(KEY_9)) {
        combo_run(Rotation);
    } else if(Rotation) combo_stop(Rotation);
 
    if(key_status(KEY_O)) {
        Toggle = FALSE;
    }
 
    // disable_touchpad
    set_val(PS4_TOUCH1, 0.0);
    set_val(PS4_TOUCH2, 0.0);
}
 
void swap(uint8 a, uint8 b) {
    fix32 tmp = get_val(a);
    set_val(a, get_val(b));
    set_val(b, tmp);
    return;
}
 
combo Synergy {
    set_val(PS4_CIRCLE, 100);
    wait(90);
    set_val(PS4_TRIANGLE, 100);
    set_val(PS4_CIRCLE, 100);
    wait(90);
    set_val(PS4_TRIANGLE, 100);
    set_val(PS4_CIRCLE, 0);
    wait(29);
    set_val(PS4_TRIANGLE, 0);
}
 
combo Ultimate {
    set_val(PS4_L1, 100);
    wait(90);
    set_val(PS4_R1, 100);
    set_val(PS4_L1, 100);
    wait(90);
    set_val(PS4_R1, 100);
    set_val(PS4_L1, 0);
    wait(29);
    set_val(PS4_R1, 0);
}
 
combo Bash {
    set_val(PS4_R2, 0);
    set_val(PS4_L2, 100);
    wait(90);
    set_val(PS4_R2, 100);
    set_val(PS4_L2, 100);
    wait(90);
    set_val(PS4_R2, 100);
    set_val(PS4_L2, 0);
    wait(29);
    set_val(PS4_R2, 0);
}
 
combo Lockpick {
    set_val(PS4_R2, 0);
    wait(100);
}
 
combo Dodge {
    set_val(PS4_L2, 100);
    wait(50);
    set_val(PS4_L2, 100);
    set_val(PS4_CROSS, 100);
    wait(100);
    set_val(PS4_L2, 100);
    set_val(PS4_CROSS, 0);
    wait(39);
    set_val(PS4_L2, 0);
}
 
combo Rotation {
    set_val(PS4_R2, 100);
    wait(100);
    set_val(PS4_R2, 0);
    wait(100);
    set_val(PS4_R1, 100);
    wait(100);
    set_val(PS4_R1, 0);
    wait(1000);
    set_val(PS4_R2, 100);
    wait(100);
    set_val(PS4_R2, 0);
    wait(100);
    set_val(PS4_L1, 100);
    wait(100);
    set_val(PS4_L1, 0);
    wait(2000);
}
 
combo InitOpenChestScript {
    //Wait for lock to load then move to far left tumbler.
    set_val(A_Button, 100);
    wait(200);
    set_val(A_Button, 0);
    wait(600);
    set_val(LeftStick_Left_Right, -100);
    wait(400);
    set_val(LeftStick_Left_Right, 0);
    TumblersToOpen = 5;
    OpeningLock = TRUE;
}
 
combo OpenChestScript {
    //Stop right trigger press and move to next tumbler.
    set_val(Right_Trigger, 0);
    set_val(LeftStick_Left_Right, 100);
    wait(200);
    set_val(LeftStick_Left_Right, 0);
    TumblersToOpen = TumblersToOpen - 1;
    if(TumblersToOpen <= 0){OpeningLock = FALSE;}//Once all pins are depressed turn off the script
}
 
combo ResetAll {
    set_val(A_Button, 0);
    set_val(Right_Trigger, 0);
    set_val(Left_Stick_Down, 0);
    set_val(Right_Stick_Down, 0);
    set_val(D_Pad_Up , 0);
    set_val(D_Pad_Right, 0);
    set_val(D_Pad_Down, 0);
    set_val(D_Pad_Left, 0);
    set_val(A_Button, 0);
    OpeningLock = FALSE;
}
 
ConsoleTuner Support Team
User avatar
J2Kbr
General of the Army
General of the Army
 
Posts: 20323
Joined: Tue Mar 18, 2014 1:39 pm
Top

Re: Can this script be converted to T2?

Postby fdg0d » Wed Dec 12, 2018 1:53 am

its working thanks :)
User avatar
fdg0d
Sergeant Major
Sergeant Major
 
Posts: 83
Joined: Thu May 12, 2016 3:16 pm
Top
Post a reply

Return to GPC2 Script Programming

Who is online

Users browsing this forum: No registered users and 113 guests