Titan Two Worth it for Fortnite Anymore

Titan Two general support. Questions, firmware update, feature request.

Titan Two Worth it for Fortnite Anymore

Postby Tru14 » Mon Dec 10, 2018 9:39 pm

Have been wanting to get this for Fortnite but with the resent editing changes, custom controller settings, and already having Aim Assist in game, is this device and the gamepack still worth the money? (I don't play anything else and won't for a while so I'd like to focus my post solely on this game) Are any of the other features of scripts/gamepacks still potent?
User avatar
Tru14
Staff Sergeant
Staff Sergeant
 
Posts: 11
Joined: Wed Aug 08, 2018 8:40 pm

Re: Titan Two Worth it for Fortnite Anymore

Postby J2Kbr » Tue Dec 11, 2018 3:33 pm

I am suspect to say, but I play Fortnite quite often and I can't really play without the Titan Two anymore. If you are interested, I use a custom script:
Code: Select all
#pragma METAINFO("Fortnite BR", 2, 0, "J2Kbr")
 
/* ************************************************************************** *
 * FORTNITE with Navigation Controller and Mouse G502 (12000DPI/1000Hz)       *
 *   Game Settings:                                                           *
 *     Region:                              Brazil                            *
 *     Controller Sensitivity X:            1.00                              *
 *     Controller Sensitivity Y:            1.00                              *
 *     Controller Targeting Sensitivity:    1.00                              *
 *     Controller Scope Sensitivity X:      0.65                              *
 *     Controller Building Sensitivity X:   1.00                              *
 *   Game Options:                          All off with following exceptions *
 *     Tap to Search / Interact:            On                                *
 *     Reset Building Choice:               On                                *
 *     Aim Assist:                          On                                *
 *     Turbo Building:                      On                                *
 *     Auto Material Change:                On                                *
 *     Auto Sort Consumables to Right:      On                                *
 *     Builder Pro: Build Immediately:      On                                *
 *     Controller Edit Hold Time:           0.25                              *
 *   Brightness:                            0.50                              *
 *   Audio:                                 0.25, 0.50, 1.00, 0.50, On, On    *
 *   Controller:                            Builder Pro                       *
 * ************************************************************************** */

#define PS4         0
#define XB1         1
#define SWITCH      2
 
#define CONSOLE     PS4
 
/* ************************************************************************** *
 * INITIALIZATION                                                             *
 * ************************************************************************** */

#include <remapper.gph>
#include <keyboard.gph>
#include <mouse.gph>
 
init {
    port_inhibit_ffb(PORT_USB_A);
 
    remapper_disable(STICK_1_X);
    remapper_disable(STICK_1_Y);
    remapper_disable(ACCEL_1_X);
    remapper_disable(ACCEL_1_Y);
    remapper_disable(ACCEL_1_Z);
    remapper_swap(BUTTON_6, BUTTON_9);
    remapper_swap(BUTTON_7, BUTTON_21);
    #if CONSOLE == SWITCH
    remapper_swap(BUTTON_15, BUTTON_16);
    #endif
    remapper_mask(RMP_USB_A | RMP_BT_A);
 
    const uint8 kmap[] = {
        KEY_P,              BUTTON_17,
        KEY_BACKSLASH,      BUTTON_3,
        KEY_OPENBRACKET,    BUTTON_19,
        KEY_CLOSEBRACKET,   BUTTON_2,
    }; keymapping(kmap);
 
    const uint8 mmap[] = {
        MOUSE_X,            STICK_1_X,
        MOUSE_Y,            STICK_1_Y,
        MWHEEL_FORWARD,     BUTTON_7,
        MWHEEL_BACKWARD,    BUTTON_4,
        MBUTTON_1,          BUTTON_5,
        MBUTTON_2,          BUTTON_16,
        MBUTTON_3,          BUTTON_9,
        MBUTTON_4,          BUTTON_20,
        MBUTTON_5,          BUTTON_14,
    }; mousemapping(mmap);
 
    #define v(n)   n >> 8, n
 
    #if CONSOLE == PS4
    const uint8 mxyc[] = {
        BUTTON_8,
        v(1.59i), // Sensitivity - Default
        0x01, 0x30, 0x00, 0x23, 0x0C, 0xF0, 0x0C, 0xF0, 0x00, 0xE5,
        0x00, 0x14, 0x1D, 0x23, 0x28, 0x2D, 0x31, 0x35, 0x38, 0x3B, 0x3E, 0x41,
        0x43, 0x46, 0x48, 0x4B, 0x4D, 0x4F, 0x52, 0x54, 0x57,
        v(1.07i), // Sensitivity - Alternate
        0x01, 0x30, 0x00, 0x23, 0x0C, 0xF0, 0x0C, 0xF0, 0x00, 0xE4,
        0x00, 0x14, 0x1D, 0x23, 0x28, 0x2D, 0x31, 0x35, 0x38, 0x3B, 0x3E, 0x41,
        0x43, 0x46, 0x48, 0x4B, 0x4D, 0x4F, 0x52, 0x54, 0x57
    }; mxyconverter(mxyc);
    #elif CONSOLE == XB1
    const uint8 mxyc[] = {
        BUTTON_8,
        v(1.12i), // Sensitivity - Default
        0x01, 0x2E, 0x00, 0x19, 0x14, 0x00, 0x14, 0x00, 0x00, 0xF8,
        0x00, 0x14, 0x1D, 0x23, 0x28, 0x2C, 0x30, 0x33, 0x36, 0x39, 0x3C, 0x3E,
        0x40, 0x42, 0x44, 0x46, 0x48, 0x4A, 0x4C, 0x4E, 0x50,
        v(0.72i), // Sensitivity - Alternate
        0x01, 0x2E, 0x00, 0x19, 0x14, 0x00, 0x14, 0x00, 0x00, 0xF7,
        0x00, 0x14, 0x1D, 0x23, 0x28, 0x2C, 0x30, 0x33, 0x36, 0x39, 0x3C, 0x3E,
        0x40, 0x42, 0x44, 0x46, 0x48, 0x4A, 0x4C, 0x4E, 0x50
    }; mxyconverter(mxyc);
    #elif CONSOLE == SWITCH
    const uint8 mxyc[] = {
        BUTTON_8,
        v(1.49i), // Sensitivity - Default
        0x01, 0x30, 0x00, 0x23, 0x07, 0xD1, 0x07, 0xD1, 0x00, 0xFF,
        0x00, 0x14, 0x1D, 0x23, 0x28, 0x2D, 0x31, 0x35, 0x38, 0x3B, 0x3E, 0x41,
        0x43, 0x46, 0x48, 0x4B, 0x4D, 0x4F, 0x52, 0x54, 0x57,
        v(1.08i), // Sensitivity - Alternate
        0x01, 0x30, 0x00, 0x23, 0x07, 0xD1, 0x07, 0xD1, 0x00, 0xFF,
        0x00, 0x14, 0x1D, 0x23, 0x28, 0x2D, 0x31, 0x35, 0x38, 0x3B, 0x3E, 0x41,
        0x43, 0x46, 0x48, 0x4B, 0x4D, 0x4F, 0x52, 0x54, 0x57
    }; mxyconverter(mxyc);
    #endif
}
 
/* ************************************************************************** *
 * MAIN                                                                       *
 * ************************************************************************** */

bool  auto_aim;
bool  edit_mode;
bool  flight_mode;
uint8 swap_weapon;
 
main {
    // Movement Stick Deadzone
    if(abs(get_val(STICK_2_X)) <= 15.0) set_val(STICK_2_X, 0.0);
    if(abs(get_val(STICK_2_Y)) <= 15.0) set_val(STICK_2_Y, 0.0);
 
    // Flight Mode
    if(event_release(BUTTON_1) && time_active(BUTTON_1) < 200) {
        flight_mode = TRUE;
        led_feedback();
    } inhibit(BUTTON_1, 200);
    if(flight_mode) {
        if(event_active(BUTTON_17)) {
            flight_mode = FALSE;
            led_feedback();
        } else {
            set_val(STICK_2_X, clamp(get_val(STICK_2_X)+get_val(STICK_1_X)* 4.0, -100.0, 100.0));
            set_val(STICK_2_Y, clamp(get_val(STICK_2_Y)+get_val(STICK_1_Y)*-4.0, -100.0, 100.0));
            set_val(STICK_1_X, 0.0);
            set_val(STICK_1_Y, 0.0);
            goto BYPASS_SCRIPT_MODS;
        }
    }
 
    // Edit Mode
    if(edit_mode) {
        if(event_active(BUTTON_15)) {
            edit_mode = FALSE;
            led_feedback();
        } else goto BYPASS_SCRIPT_MODS;
    }
    // Enter Edit Mode
    if(get_val(BUTTON_15) && time_active(BUTTON_15) > 256) {
        edit_mode = TRUE;
        led_feedback();
        goto BYPASS_SCRIPT_MODS;
    }
 
    // Auto Aim
    if(event_active(BUTTON_5)) {
        auto_aim = TRUE;
    } else if(event_release(BUTTON_8) || (event_release(BUTTON_5) && is_release(BUTTON_8))) {
        auto_aim = FALSE;
    }
    if(auto_aim) {
        combo_run(AutoAim);
    }
    // No Auto Aiming Fire
    if(get_val(BUTTON_8) && get_val(BUTTON_19)) {
        set_val(BUTTON_5, 100.0);
        set_val(BUTTON_19, 0.0);
    }
 
    // Harvest and Driving
    if(get_val(BUTTON_14)) {
        if(event_active(BUTTON_14)) {
            combo_run(Harvest);
        } else if(!Harvest) {
            combo_run(TurboHarvest);
        }
        if(get_val(BUTTON_21)) {
            set_val(BUTTON_7, 100.0);
            goto BYPASS_SCRIPT_MODS;
        }
    } else if(event_release(BUTTON_14)) {
        combo_run(Harvest);
    } set_val(BUTTON_14, 0.0);
 
    // Rapidfire
    if(get_val(BUTTON_5)) {
        combo_run(Rapidfire);
    }
 
    // Auto Swap Weapon
    if(swap_weapon) {
        if(event_active(BUTTON_5)) {
            combo_run(SwapWeapon);
        }
        if(event_active(BUTTON_4) || event_active(BUTTON_7)) {
            swap_weapon = 0;
            led_feedback();
        }
    }
    if(get_val(BUTTON_17)) {
        if(event_active(BUTTON_4)) {
            swap_weapon = BUTTON_4;
            led_feedback();
        } set_val(BUTTON_4, 0.0);
        if(event_active(BUTTON_7)) {
            swap_weapon = BUTTON_7;
            led_feedback();
        } set_val(BUTTON_7, 0.0);
    }
 
    // Instant Build
    if(!(InstaBuildWall || InstaBuildStair || InstaBuildFloor)) {
        if(get_val(BUTTON_21)) {
            combo_run(InstaBuildWall);
        }
        if(get_val(BUTTON_20)) {
            combo_run(InstaBuildStair);
        }
        if(get_val(BUTTON_19)) {
            combo_run(InstaBuildFloor);
        }
    } else goto BYPASS_SCRIPT_MODS;
 
    // Instant Trap
    bool insta_trap;
    if(key_status(KEY_SEMICOLON)) {
        if(!insta_trap) {
            insta_trap = TRUE;
            combo_run(InstaTrapSelect);
        }
    } else if(key_status(KEY_QUOTE)) {
        if(!insta_trap) {
            insta_trap = TRUE;
            combo_run(InstaTrapPlace);
        }
    } else insta_trap = FALSE;
 
    BYPASS_SCRIPT_MODS:;
    // Switch Inventory Button Swap
    #if CONSOLE == SWITCH
    static bool inventory;
    if(event_active(BUTTON_10)) {
        inventory = TRUE;
    }
    if(inventory) {
        if(mouse_status(MBUTTON_2)) {
            set_val(BUTTON_15, 100.0);
            set_val(BUTTON_16, 0.0);
        } else if(get_val(BUTTON_16)) {
            inventory = FALSE;
        }
    }
    #endif
}
 
/* ************************************************************************** *
 * FUNCTIONS                                                                  *
 * ************************************************************************** */

void led_feedback() {
    led_reset();
    if(flight_mode) {
        led_set(LED_3, -1.0, 0);
        led_set(LED_4, -1.0, 0);
    } else if(edit_mode) {
        led_set(LED_4, -1.0, 0);
    } else if(swap_weapon == BUTTON_4) {
        led_set(LED_2, -1.0, 0);
    } else if(swap_weapon == BUTTON_7) {
        led_set(LED_3, -1.0, 0);
    }
    return;
}
 
/* ************************************************************************** *
 * COMBOS                                                                     *
 * ************************************************************************** */

combo Harvest {
    set_val(BUTTON_14, 100.0);
    wait(48); wait(48);
}
 
combo TurboHarvest {
    set_val(BUTTON_5, 100.0);
}
 
combo Rapidfire {
    set_val(BUTTON_5, 100.0);
    wait(64);
    set_val(BUTTON_5, 0.0);
    wait(16);
    set_val(BUTTON_5, 0.0);
}
 
combo SwapWeapon {
    wait(80);
    set_val(swap_weapon, 100.0);
    wait(40);
    swap_weapon = 0;
    led_feedback();
}
 
combo AutoAim {
    set_val(BUTTON_8, 100.0);
    wait(150);
    set_val(BUTTON_8, 0.0);
    wait(50);
    set_val(BUTTON_8, 0.0);
}
 
combo InstaBuildWall {
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_5, 100.0);
    wait(128);
    if(get_val(BUTTON_21)) {
        InstaBuildWall[1] = 3;
        set_val(BUTTON_5, 100.0);
    } else set_val(BUTTON_5, 0.0);
    wait(48);
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
}
 
combo InstaBuildStair {
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_9, 100.0);
    set_val(BUTTON_8, 100.0);
    wait(64);
    set_val(BUTTON_8, 100.0);
    wait(64);
    if(get_val(BUTTON_20)) {
        InstaBuildStair[1] = 3;
        set_val(BUTTON_8, 100.0);
    } else set_val(BUTTON_8, 0.0);
    wait(48);
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
}
 
combo InstaBuildFloor {
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_9, 100.0);
    set_val(BUTTON_4, 100.0);
    wait(64);
    set_val(BUTTON_4, 100.0);
    wait(64);
    if(get_val(BUTTON_19)) {
        InstaBuildFloor[1] = 3;
        set_val(BUTTON_4, 100.0);
    } else set_val(BUTTON_4, 0.0);
    wait(48);
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
}
 
combo InstaTrapSelect {
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_17, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_6, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
}
 
combo InstaTrapPlace {
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_17, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_17, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
}
 
ConsoleTuner Support Team
User avatar
J2Kbr
General of the Army
General of the Army
 
Posts: 20323
Joined: Tue Mar 18, 2014 1:39 pm

Re: Titan Two Worth it for Fortnite Anymore

Postby Tru14 » Tue Dec 11, 2018 8:39 pm

Thank you for sharing your input and your custom script. I assume the code above would need to be remapped for how I play (as I do not know what BUTTON_15 is, etc.)? The sensitivity settings would overwrite the in game settings? Not sure how the hex code for sensitivity is understood or if it can be omitted?

Also, would you mind helping me understand your auto aim (or any script/gamepack's auto aim) versus what the ingame aim assist does? I see it in all Fortnite scripts but when I watch youtube videos on them I notice there is still plenty of missing shots so what is the differences between the two?

Thank you for your time.
User avatar
Tru14
Staff Sergeant
Staff Sergeant
 
Posts: 11
Joined: Wed Aug 08, 2018 8:40 pm

Re: Titan Two Worth it for Fortnite Anymore

Postby J2Kbr » Wed Dec 12, 2018 8:06 am

The aim assist abuse mod constantly press and release the aiming button to trigger the aim assist of the game (based on the press and release values configured on the Gamepack or script).

The effect of this is snap the aim reticle on the enemy, normally very effective in campaign mode and also with Fortnite. However, the aim assist on most multiplayer games is reduced or nonexistent.
ConsoleTuner Support Team
User avatar
J2Kbr
General of the Army
General of the Army
 
Posts: 20323
Joined: Tue Mar 18, 2014 1:39 pm

Re: Titan Two Worth it for Fortnite Anymore

Postby zodx » Wed Dec 19, 2018 10:21 am

ignore
Last edited by zodx on Thu Dec 20, 2018 10:31 am, edited 1 time in total.
User avatar
zodx
Sergeant First Class
Sergeant First Class
 
Posts: 23
Joined: Fri Jun 22, 2018 7:54 am

Re: Titan Two Worth it for Fortnite Anymore

Postby xb1 » Wed Dec 19, 2018 3:38 pm

Aim assist in game slows down and pulls your reticle toward the body of opponents

Aim Down Sight Spam resets your first shot accuracy more quickly to reduce bloom and get more pulls from the in game aim assist

Scripts with auto aim mean you can just hold fire hip or ADS and your shots will track the enemies
Alan McGregor has an example of this on YouTube with an SMG

I believe if you don’t get constant disconnects like a lot of people have been getting, and fortnite is your main game, it’s still super worth it because your effective aim and damage to opponents will greatly improve. You can turn 50/50 battles odds in your favor and become a beast from medium and long range with ARs with its help
User avatar
xb1
Master Sergeant
Master Sergeant
 
Posts: 38
Joined: Thu Dec 13, 2018 1:43 am

Re: Titan Two Worth it for Fortnite Anymore

Postby teckx » Sun Dec 30, 2018 1:51 am

J2Kbr wrote:I am suspect to say, but I play Fortnite quite often and I can't really play without the Titan Two anymore. If you are interested, I use a custom script:
Code: Select all
#pragma METAINFO("Fortnite BR", 2, 0, "J2Kbr")
 
/* ************************************************************************** *
 * FORTNITE with Navigation Controller and Mouse G502 (12000DPI/1000Hz)       *
 *   Game Settings:                                                           *
 *     Region:                              Brazil                            *
 *     Controller Sensitivity X:            1.00                              *
 *     Controller Sensitivity Y:            1.00                              *
 *     Controller Targeting Sensitivity:    1.00                              *
 *     Controller Scope Sensitivity X:      0.65                              *
 *     Controller Building Sensitivity X:   1.00                              *
 *   Game Options:                          All off with following exceptions *
 *     Tap to Search / Interact:            On                                *
 *     Reset Building Choice:               On                                *
 *     Aim Assist:                          On                                *
 *     Turbo Building:                      On                                *
 *     Auto Material Change:                On                                *
 *     Auto Sort Consumables to Right:      On                                *
 *     Builder Pro: Build Immediately:      On                                *
 *     Controller Edit Hold Time:           0.25                              *
 *   Brightness:                            0.50                              *
 *   Audio:                                 0.25, 0.50, 1.00, 0.50, On, On    *
 *   Controller:                            Builder Pro                       *
 * ************************************************************************** */

#define PS4         0
#define XB1         1
#define SWITCH      2
 
#define CONSOLE     PS4
 
/* ************************************************************************** *
 * INITIALIZATION                                                             *
 * ************************************************************************** */

#include <remapper.gph>
#include <keyboard.gph>
#include <mouse.gph>
 
init {
    port_inhibit_ffb(PORT_USB_A);
 
    remapper_disable(STICK_1_X);
    remapper_disable(STICK_1_Y);
    remapper_disable(ACCEL_1_X);
    remapper_disable(ACCEL_1_Y);
    remapper_disable(ACCEL_1_Z);
    remapper_swap(BUTTON_6, BUTTON_9);
    remapper_swap(BUTTON_7, BUTTON_21);
    #if CONSOLE == SWITCH
    remapper_swap(BUTTON_15, BUTTON_16);
    #endif
    remapper_mask(RMP_USB_A | RMP_BT_A);
 
    const uint8 kmap[] = {
        KEY_P,              BUTTON_17,
        KEY_BACKSLASH,      BUTTON_3,
        KEY_OPENBRACKET,    BUTTON_19,
        KEY_CLOSEBRACKET,   BUTTON_2,
    }; keymapping(kmap);
 
    const uint8 mmap[] = {
        MOUSE_X,            STICK_1_X,
        MOUSE_Y,            STICK_1_Y,
        MWHEEL_FORWARD,     BUTTON_7,
        MWHEEL_BACKWARD,    BUTTON_4,
        MBUTTON_1,          BUTTON_5,
        MBUTTON_2,          BUTTON_16,
        MBUTTON_3,          BUTTON_9,
        MBUTTON_4,          BUTTON_20,
        MBUTTON_5,          BUTTON_14,
    }; mousemapping(mmap);
 
    #define v(n)   n >> 8, n
 
    #if CONSOLE == PS4
    const uint8 mxyc[] = {
        BUTTON_8,
        v(1.59i), // Sensitivity - Default
        0x01, 0x30, 0x00, 0x23, 0x0C, 0xF0, 0x0C, 0xF0, 0x00, 0xE5,
        0x00, 0x14, 0x1D, 0x23, 0x28, 0x2D, 0x31, 0x35, 0x38, 0x3B, 0x3E, 0x41,
        0x43, 0x46, 0x48, 0x4B, 0x4D, 0x4F, 0x52, 0x54, 0x57,
        v(1.07i), // Sensitivity - Alternate
        0x01, 0x30, 0x00, 0x23, 0x0C, 0xF0, 0x0C, 0xF0, 0x00, 0xE4,
        0x00, 0x14, 0x1D, 0x23, 0x28, 0x2D, 0x31, 0x35, 0x38, 0x3B, 0x3E, 0x41,
        0x43, 0x46, 0x48, 0x4B, 0x4D, 0x4F, 0x52, 0x54, 0x57
    }; mxyconverter(mxyc);
    #elif CONSOLE == XB1
    const uint8 mxyc[] = {
        BUTTON_8,
        v(1.12i), // Sensitivity - Default
        0x01, 0x2E, 0x00, 0x19, 0x14, 0x00, 0x14, 0x00, 0x00, 0xF8,
        0x00, 0x14, 0x1D, 0x23, 0x28, 0x2C, 0x30, 0x33, 0x36, 0x39, 0x3C, 0x3E,
        0x40, 0x42, 0x44, 0x46, 0x48, 0x4A, 0x4C, 0x4E, 0x50,
        v(0.72i), // Sensitivity - Alternate
        0x01, 0x2E, 0x00, 0x19, 0x14, 0x00, 0x14, 0x00, 0x00, 0xF7,
        0x00, 0x14, 0x1D, 0x23, 0x28, 0x2C, 0x30, 0x33, 0x36, 0x39, 0x3C, 0x3E,
        0x40, 0x42, 0x44, 0x46, 0x48, 0x4A, 0x4C, 0x4E, 0x50
    }; mxyconverter(mxyc);
    #elif CONSOLE == SWITCH
    const uint8 mxyc[] = {
        BUTTON_8,
        v(1.49i), // Sensitivity - Default
        0x01, 0x30, 0x00, 0x23, 0x07, 0xD1, 0x07, 0xD1, 0x00, 0xFF,
        0x00, 0x14, 0x1D, 0x23, 0x28, 0x2D, 0x31, 0x35, 0x38, 0x3B, 0x3E, 0x41,
        0x43, 0x46, 0x48, 0x4B, 0x4D, 0x4F, 0x52, 0x54, 0x57,
        v(1.08i), // Sensitivity - Alternate
        0x01, 0x30, 0x00, 0x23, 0x07, 0xD1, 0x07, 0xD1, 0x00, 0xFF,
        0x00, 0x14, 0x1D, 0x23, 0x28, 0x2D, 0x31, 0x35, 0x38, 0x3B, 0x3E, 0x41,
        0x43, 0x46, 0x48, 0x4B, 0x4D, 0x4F, 0x52, 0x54, 0x57
    }; mxyconverter(mxyc);
    #endif
}
 
/* ************************************************************************** *
 * MAIN                                                                       *
 * ************************************************************************** */

bool  auto_aim;
bool  edit_mode;
bool  flight_mode;
uint8 swap_weapon;
 
main {
    // Movement Stick Deadzone
    if(abs(get_val(STICK_2_X)) <= 15.0) set_val(STICK_2_X, 0.0);
    if(abs(get_val(STICK_2_Y)) <= 15.0) set_val(STICK_2_Y, 0.0);
 
    // Flight Mode
    if(event_release(BUTTON_1) && time_active(BUTTON_1) < 200) {
        flight_mode = TRUE;
        led_feedback();
    } inhibit(BUTTON_1, 200);
    if(flight_mode) {
        if(event_active(BUTTON_17)) {
            flight_mode = FALSE;
            led_feedback();
        } else {
            set_val(STICK_2_X, clamp(get_val(STICK_2_X)+get_val(STICK_1_X)* 4.0, -100.0, 100.0));
            set_val(STICK_2_Y, clamp(get_val(STICK_2_Y)+get_val(STICK_1_Y)*-4.0, -100.0, 100.0));
            set_val(STICK_1_X, 0.0);
            set_val(STICK_1_Y, 0.0);
            goto BYPASS_SCRIPT_MODS;
        }
    }
 
    // Edit Mode
    if(edit_mode) {
        if(event_active(BUTTON_15)) {
            edit_mode = FALSE;
            led_feedback();
        } else goto BYPASS_SCRIPT_MODS;
    }
    // Enter Edit Mode
    if(get_val(BUTTON_15) && time_active(BUTTON_15) > 256) {
        edit_mode = TRUE;
        led_feedback();
        goto BYPASS_SCRIPT_MODS;
    }
 
    // Auto Aim
    if(event_active(BUTTON_5)) {
        auto_aim = TRUE;
    } else if(event_release(BUTTON_8) || (event_release(BUTTON_5) && is_release(BUTTON_8))) {
        auto_aim = FALSE;
    }
    if(auto_aim) {
        combo_run(AutoAim);
    }
    // No Auto Aiming Fire
    if(get_val(BUTTON_8) && get_val(BUTTON_19)) {
        set_val(BUTTON_5, 100.0);
        set_val(BUTTON_19, 0.0);
    }
 
    // Harvest and Driving
    if(get_val(BUTTON_14)) {
        if(event_active(BUTTON_14)) {
            combo_run(Harvest);
        } else if(!Harvest) {
            combo_run(TurboHarvest);
        }
        if(get_val(BUTTON_21)) {
            set_val(BUTTON_7, 100.0);
            goto BYPASS_SCRIPT_MODS;
        }
    } else if(event_release(BUTTON_14)) {
        combo_run(Harvest);
    } set_val(BUTTON_14, 0.0);
 
    // Rapidfire
    if(get_val(BUTTON_5)) {
        combo_run(Rapidfire);
    }
 
    // Auto Swap Weapon
    if(swap_weapon) {
        if(event_active(BUTTON_5)) {
            combo_run(SwapWeapon);
        }
        if(event_active(BUTTON_4) || event_active(BUTTON_7)) {
            swap_weapon = 0;
            led_feedback();
        }
    }
    if(get_val(BUTTON_17)) {
        if(event_active(BUTTON_4)) {
            swap_weapon = BUTTON_4;
            led_feedback();
        } set_val(BUTTON_4, 0.0);
        if(event_active(BUTTON_7)) {
            swap_weapon = BUTTON_7;
            led_feedback();
        } set_val(BUTTON_7, 0.0);
    }
 
    // Instant Build
    if(!(InstaBuildWall || InstaBuildStair || InstaBuildFloor)) {
        if(get_val(BUTTON_21)) {
            combo_run(InstaBuildWall);
        }
        if(get_val(BUTTON_20)) {
            combo_run(InstaBuildStair);
        }
        if(get_val(BUTTON_19)) {
            combo_run(InstaBuildFloor);
        }
    } else goto BYPASS_SCRIPT_MODS;
 
    // Instant Trap
    bool insta_trap;
    if(key_status(KEY_SEMICOLON)) {
        if(!insta_trap) {
            insta_trap = TRUE;
            combo_run(InstaTrapSelect);
        }
    } else if(key_status(KEY_QUOTE)) {
        if(!insta_trap) {
            insta_trap = TRUE;
            combo_run(InstaTrapPlace);
        }
    } else insta_trap = FALSE;
 
    BYPASS_SCRIPT_MODS:;
    // Switch Inventory Button Swap
    #if CONSOLE == SWITCH
    static bool inventory;
    if(event_active(BUTTON_10)) {
        inventory = TRUE;
    }
    if(inventory) {
        if(mouse_status(MBUTTON_2)) {
            set_val(BUTTON_15, 100.0);
            set_val(BUTTON_16, 0.0);
        } else if(get_val(BUTTON_16)) {
            inventory = FALSE;
        }
    }
    #endif
}
 
/* ************************************************************************** *
 * FUNCTIONS                                                                  *
 * ************************************************************************** */

void led_feedback() {
    led_reset();
    if(flight_mode) {
        led_set(LED_3, -1.0, 0);
        led_set(LED_4, -1.0, 0);
    } else if(edit_mode) {
        led_set(LED_4, -1.0, 0);
    } else if(swap_weapon == BUTTON_4) {
        led_set(LED_2, -1.0, 0);
    } else if(swap_weapon == BUTTON_7) {
        led_set(LED_3, -1.0, 0);
    }
    return;
}
 
/* ************************************************************************** *
 * COMBOS                                                                     *
 * ************************************************************************** */

combo Harvest {
    set_val(BUTTON_14, 100.0);
    wait(48); wait(48);
}
 
combo TurboHarvest {
    set_val(BUTTON_5, 100.0);
}
 
combo Rapidfire {
    set_val(BUTTON_5, 100.0);
    wait(64);
    set_val(BUTTON_5, 0.0);
    wait(16);
    set_val(BUTTON_5, 0.0);
}
 
combo SwapWeapon {
    wait(80);
    set_val(swap_weapon, 100.0);
    wait(40);
    swap_weapon = 0;
    led_feedback();
}
 
combo AutoAim {
    set_val(BUTTON_8, 100.0);
    wait(150);
    set_val(BUTTON_8, 0.0);
    wait(50);
    set_val(BUTTON_8, 0.0);
}
 
combo InstaBuildWall {
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_5, 100.0);
    wait(128);
    if(get_val(BUTTON_21)) {
        InstaBuildWall[1] = 3;
        set_val(BUTTON_5, 100.0);
    } else set_val(BUTTON_5, 0.0);
    wait(48);
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
}
 
combo InstaBuildStair {
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_9, 100.0);
    set_val(BUTTON_8, 100.0);
    wait(64);
    set_val(BUTTON_8, 100.0);
    wait(64);
    if(get_val(BUTTON_20)) {
        InstaBuildStair[1] = 3;
        set_val(BUTTON_8, 100.0);
    } else set_val(BUTTON_8, 0.0);
    wait(48);
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
}
 
combo InstaBuildFloor {
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_9, 100.0);
    set_val(BUTTON_4, 100.0);
    wait(64);
    set_val(BUTTON_4, 100.0);
    wait(64);
    if(get_val(BUTTON_19)) {
        InstaBuildFloor[1] = 3;
        set_val(BUTTON_4, 100.0);
    } else set_val(BUTTON_4, 0.0);
    wait(48);
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
}
 
combo InstaTrapSelect {
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_17, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_6, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
}
 
combo InstaTrapPlace {
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_17, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_17, 100.0);
    wait(48); wait(48);
    set_val(BUTTON_15, 100.0);
    wait(48); wait(48);
}
 


Which controller setup are you using. Builder pro?
User avatar
teckx
Sergeant Major of the Army
Sergeant Major of the Army
 
Posts: 194
Joined: Tue Mar 27, 2018 1:53 pm

Re: Titan Two Worth it for Fortnite Anymore

Postby bonefisher » Sun Dec 30, 2018 7:52 am

He is using PS4!
bonefisher
Lieutenant General
Lieutenant General
 
Posts: 5413
Joined: Thu Jan 29, 2015 10:49 am

Re: Titan Two Worth it for Fortnite Anymore

Postby J2Kbr » Sun Dec 30, 2018 9:23 am

teckx wrote:Which controller setup are you using. Builder pro?

Correct, with this version of the script the button layout is Builder Pro. Helps place the build pieces faster.
ConsoleTuner Support Team
User avatar
J2Kbr
General of the Army
General of the Army
 
Posts: 20323
Joined: Tue Mar 18, 2014 1:39 pm

Re: Titan Two Worth it for Fortnite Anymore

Postby Antec800 » Sun Dec 30, 2018 2:43 pm

J2Kbr wrote:
teckx wrote:Which controller setup are you using. Builder pro?

Correct, with this version of the script the button layout is Builder Pro. Helps place the build pieces faster.

Is this script better then the gamepack?
User avatar
Antec800
First Sergeant
First Sergeant
 
Posts: 45
Joined: Tue Oct 30, 2018 3:34 am

Next

Return to Titan Two Device

Who is online

Users browsing this forum: No registered users and 71 guests