Converter para Titan one

[ACSniper]

Alguém pode converter este script para T one, agradeço pela ajuda.

Code: Select all

#pragma METAINFO("QuickStandardAbuse", 1, 0, "bonefisher")
 
#define quick_scope_delay        240
#define hold_abuse_adjustment    150
#define release_abuse_adjustment 40
 
bool   toggle_LT;
uint32 time_counter;
 
main {
    if(event_release(BUTTON_8) && time_active(BUTTON_8) < 200) {
        combo_run(one_shot);
    }
    if(event_active(BUTTON_8)&&time_release(BUTTON_8)< 200){
        toggle_LT = 1;
    }else if(event_release(BUTTON_8)){
        toggle_LT = 0;
    }
    if(toggle_LT == 1){ 
    if(get_actual(BUTTON_8) && time_active(BUTTON_8) > 100) {
    time_counter += elapsed_time();
    if(time_counter >= hold_abuse_adjustment) {
        time_counter = 0;
        combo_run(aim_abuse);
    }
    }
    }
}
combo aim_abuse {
    set_val(BUTTON_8, 0.0);
    wait(release_abuse_adjustment);
}
 
combo one_shot
{
    set_val(BUTTON_8, 100.0);
    wait(quick_scope_delay); 
    set_val(BUTTON_8, 100.0);
    set_val(BUTTON_5, 100.0);
    wait(60);
    set_val(BUTTON_8, 100.0);
    wait(40);
}

[J2Kbr]

Converted.

Code: Select all

define quick_scope_delay        = 240;
define hold_abuse_adjustment    = 150;
define release_abuse_adjustment = 40;
 
int toggle_LT;
int time_counter;
 
main {
    if(event_release(PS4_L2) && get_ptime(PS4_L2) < 200) {
        combo_run(one_shot);
    }
    if(event_press(PS4_L2)){
        toggle_LT = 1;
    }else if(event_release(PS4_L2)){
        toggle_LT = 0;
    }
    if(toggle_LT == 1){ 
        if(get_val(PS4_L2) && get_ptime(PS4_L2) > 100) {
            time_counter = time_counter + get_rtime();
            if(time_counter >= hold_abuse_adjustment) {
                time_counter = 0;
                combo_run(aim_abuse);
            }
        }
    }
}
 
combo aim_abuse {
    set_val(PS4_L2, 0);
    wait(release_abuse_adjustment);
}
 
combo one_shot
{
    set_val(PS4_L2, 100);
    wait(quick_scope_delay); 
    set_val(PS4_L2, 100);
    set_val(PS4_R2, 100);
    wait(60);
    set_val(PS4_L2, 100);
    wait(40);
}