Simple Question?

[HelpMePlez]

Can someone please help me to make a small change to the current script I am using

Code: Select all

unmap PS4_SHARE;
unmap PS4_ACCX;
unmap PS4_ACCY;
unmap PS4_ACCZ;
remap XB1_VIEW -> PS4_TOUCH;
int last_ps4_auth_timeout;
 
main {
    // Rumble the controller if the PS4 auth timeout gets below 5.
    if(ps4_authtimeout() < 5) {
        if(last_ps4_auth_timeout != ps4_authtimeout()) {
            last_ps4_auth_timeout = ps4_authtimeout();
            combo_restart(AuthRumbleFeedback);
        }
    }
    // Press OPTIONS + PS to force reconnection and reset auth timeout.
    if(get_val(PS4_OPTIONS) && event_press(PS4_PS)) {
        output_reconnection();
    }
}
 
combo AuthRumbleFeedback {
    set_rumble(RUMBLE_A, 100);
    set_rumble(RUMBLE_B, 100);
    wait(200);
    reset_rumble();
}

I really like the PS4 Force Reconnection but I don't like that it rumbles below 5 Min

I would like to remove the rumble completely from the script.
And instead of pressing Options + PS to reset the timer I would like to Press 2 Times down on the D-Pad
If 2 Times pressing Down on the D-Pad is not possible 1 Time is also good for me.

If someone can make this change for me and merge it with the above script that would be really nice.

Thanks!

[UK_Wildcats]

See if this works.

Code: Select all

unmap PS4_SHARE;
unmap PS4_ACCX;
unmap PS4_ACCY;
unmap PS4_ACCZ;
remap XB1_VIEW -> PS4_TOUCH;
int last_ps4_auth_timeout;
int Timer1;
 
main {

    // Timer - Countdown function
    if (Timer1 > 0) { Timer1 = Timer1 - get_rtime(); }    // Reduce the timer value by the elapsed run time

    // Timer - Detection of the release
    if (event_release(PS4_DOWN)) {
        Timer1 = 300;   // 300 ms timer (starting the timer)
    }   

    // Timer - Detection of the press
    if (event_press(PS4_DOWN) && Timer1 > 0) {
        Timer1 = 0;
        output_reconnection();
    }

}
 

[HelpMePlez]

Works Perfect!

Thanks for helping me!

[UK_Wildcats]

You're welcome. I am happy to help.