Rainbox Six: Seige Gamepack

[Squidward]

I have some ideas for a Rainbox Six: Seige gamepack.

Of course there are the obvious ones, like side shot, drop shot, rapid fire for semi auto weapons, turbo melee, etc.

But I think the one I want to try out more than anything else would be auto aiming-- Bascially, having the Titan One spam ADS (left trigger) to auto aim head shots. I have noticed while playing that if I quick-aim down sights and fire immediately that I can basically headshot all day long. If the Titan One can auto aim for me, I think I'd be unstoppable. One thing I'd like for this auto aim mod would be the ability to toggle it on/off by doing a button combo such as d-pad up+left trigger. That way I don't have to auto aim at all times.

What do you think?

[bonefisher]

I'll build one tonight and let you try it.

[Squidward]

I'll build one tonight and let you try it.

Awesome, thank you!

[Squidward]

@J2Kbr any chance of getting a gamepack for Rainbow Six?

[bonefisher]

Almost done with something you can use for the time being.

[Squidward]

Almost done with something you can use for the time being.

Ok, sweet. I definitely plan on trying it out and reporting back! Can you include, in your script, a toggle to turn rapid fire and the ADS auto aim on/off by pressing d-pad-up+left trigger (for auto aim) and d-pad-up+right trigger (for rapid fire)? BTW, I have Rainbow Six on the Xbox One, not PS4.

[bonefisher]

Code: Select all


define FIRE_BUTTON               = XB1_RT;
define DROP_BUTTON               = XB1_B;
define GAME_Y_AIM                = XB1_RY;

define RATE_OF_FIRE1             = 20;      // Range: 1 to 25 SPS. Rapid Fire 1
define RATE_OF_FIRE2             = 21.4;    // Range: 1 to 25 SPS. Rapid Fire 2
define RATE_OF_BURST1            = 200;     // Burst1 and Delay1 go together making your automatic
define RATE_OF_DELAY1            = 30;      // burst or controlling them or exact rpm for burst rifles.
define RATE_OF_BURST2            = 300;     // Burst2 and Delay2 go together making your automatic
define RATE_OF_DELAY2            = 150;     // burst or controlling them or exact rpm for burst rifles.

define ANTI_RECOIL               = 35;      // change this value to compensate to the vertical recoil
define ANTI_RECOIL_LEFT          = 2;       // change this value to compensate to the left
define ANTI_RECOIL_RIGHT         = 0;       // change this value to compensate to the right

define ANTI_RECOIL_FORCE         = 35;      // change this value to compensate to the vertical recoil for advance rapid fire.
define ANTI_RECOIL_FORCE2        = 35;      // change this value to compensate to the vertical recoil for advance rapid fire.
define ONLY_WITH_SCOPE           = TRUE;
define Y_wait                    = 1000;    // can adjust to ensure enough time for switching
define R_wait                    = 2300;    // can adjust to ensure enough time to reload

int rapid1_onoff                 = FALSE;
int rapid2_onoff                 = FALSE;
int rapid3_onoff                 = FALSE;
int rapid4_onoff                 = FALSE;

int hold_time1, rest_time1;
int hold_time2, rest_time2;
int hold_time3, rest_time3;
int hold_time4, rest_time4;
int dropshot_toggle              = FALSE;
int AntiRecoilON                 = FALSE;
int spamLT_onoff                 = FALSE;

int prone_flag;

int anti_recoil;
int anti_recoil_left;
int anti_recoil_right;

int ar_fire, ar_tmp;

init {
    hold_time1 = 500 / RATE_OF_FIRE1;
    rest_time1 = hold_time1;
    if(rest_time1 < 0) rest_time1 = 0;
   
    hold_time2 = 500 / RATE_OF_FIRE2;
    rest_time2 = hold_time2;
    if(rest_time2 < 0) rest_time2 = 0;
   
    hold_time3 = RATE_OF_BURST1;
    rest_time3 = RATE_OF_DELAY1;
    if(rest_time3 < 0) rest_time3 = 0;
   
    hold_time4 = RATE_OF_BURST2;
    rest_time4 = RATE_OF_DELAY2;
    if(rest_time4 < 0) rest_time4 = 0;
}

main {
    vm_tctrl(-8);
    ar_fire = get_val(FIRE_BUTTON);

    if((event_press(XB1_LT) && get_val(XB1_LEFT)) || (event_press(XB1_LEFT) && get_val(XB1_LT))){       // TURN ON/OFF Rapid Fire.
        rapid1_onoff = !rapid1_onoff;                                                                   // Change RATE_OF_FIRE1 in define section.
        if(rapid1_onoff) combo_run(RumbleNotifier);
        rapid2_onoff = FALSE;
        rapid3_onoff = FALSE;
        rapid4_onoff = FALSE; }
     
    if(get_val(XB1_RT) && rapid1_onoff) {combo_run(RapidFire1); }
   
    if((event_press(XB1_LT) && get_val(XB1_UP)) || (event_press(XB1_UP) && get_val(XB1_LT))){           // Turns ON/OFF Rapid Fire 2
        rapid2_onoff = !rapid2_onoff;                                                                   // Change RATE_OF_FIRE2 in define section.
        if(rapid2_onoff) combo_run(RumbleNotifier);
        rapid1_onoff = FALSE;
        rapid3_onoff = FALSE;
        rapid4_onoff = FALSE; }

    if(rapid2_onoff && get_val(XB1_RT)) {combo_run(RapidFire2);
       combo_run(AntiRecoilADV); }
       
    if((event_press(XB1_LT) && get_val(XB1_RIGHT)) || (event_press(XB1_RIGHT) && get_val(XB1_LT))){     // Turns ON/OFF BURST1 and DELAY1
        rapid3_onoff = !rapid3_onoff;                                                                   // Change in define section.
        if(rapid3_onoff) combo_run(RumbleNotifier);
        rapid1_onoff = FALSE;
        rapid2_onoff = FALSE;
        rapid4_onoff = FALSE; }

    if(rapid3_onoff && get_val(XB1_RT)) {combo_run(RapidFire3);
       combo_run(AntiRecoilADV); }
   
    if((event_press(XB1_LT) && get_val(XB1_DOWN)) || (event_press( XB1_DOWN) && get_val(XB1_LT))) {     // Turns ON/OFF BURST2 and DELAY2
        rapid4_onoff = !rapid4_onoff;                                                                   // Change in define section.
        if(rapid4_onoff) combo_run(RumbleNotifier);
        rapid1_onoff = FALSE;
        rapid2_onoff = FALSE;
        rapid3_onoff = FALSE; }
       
    if(rapid4_onoff && get_val(XB1_RT)) {combo_run(RapidFire4);
        combo_run(AntiRecoilADV2); }
       
    if(get_val(XB1_LEFT) && event_press(XB1_A)) {                                                       // Turns on/ off spam LT D-pad Left + A button
        spamLT_onoff = !spamLT_onoff;
        if(spamLT_onoff) combo_run(RumbleNotifier); }
       
    if(spamLT_onoff && get_val(XB1_RT)) {combo_run(SPAM_LT); }

    if(get_val(XB1_LEFT) && event_press(XB1_B)) {                                                       // This turns on/off dropshot. D-Pad Left + B button
        dropshot_toggle = !dropshot_toggle;
        if(dropshot_toggle) combo_run(RumbleNotifier);
    }
    if(dropshot_toggle) {
        if((!get_val(XB1_LT) && event_press(FIRE_BUTTON)) || (event_release(XB1_LT) && get_val(FIRE_BUTTON))) {
        combo_run(Prone);
        combo_stop(AutoSprint); }
        else if(event_release(FIRE_BUTTON)) {
        if(prone_flag) combo_run(Stand);
        combo_stop(AutoSprint); }
    }
    if(get_val(XB1_LEFT) && event_press(XB1_RS)) {                                                      // This turns on/off Anti-Recoil.
        AntiRecoilON = !AntiRecoilON;
        if(AntiRecoilON) combo_run(RumbleNotifier);
    }
    if(AntiRecoilON && (ONLY_WITH_SCOPE || get_val(XB1_LT))) {
        combo_run(AntiRecoil);
    }
   
    if(get_val(XB1_LY) < -99 && !combo_running(AllowReloading) && !combo_running(AllowSwitching)) { combo_run(AutoSprint); }
    else if((get_val(XB1_LY) > -99)) {combo_stop(AutoSprint); } // Reload will also stop
   
    if(event_press(XB1_X)) {combo_stop(AutoSprint); combo_run(AllowReloading);}  // Stop auto sprint to allow reloading
   
    if(get_val(XB1_Y)) {combo_stop(AutoSprint); combo_run(AllowSwitching);}    // Stop auto sprint to allow switching
   
    if(get_val(XB1_P4)) {
        combo_run(LeftLean);
    }
    if(get_val(XB1_P3)) {
        combo_run(Vault_Rappel);
    }
    if(get_val(XB1_P2)) {
        combo_run(RightLean)
    }
    if(get_val(XB1_P1)) {
        combo_run(Drop_Stand);
    }
}
   
combo RapidFire1 {
    set_val(FIRE_BUTTON, 100);
    wait(hold_time1);
    set_val(FIRE_BUTTON, 0);
    wait(rest_time1);
    set_val(FIRE_BUTTON, 0);
}

combo RapidFire2 {
    set_val(FIRE_BUTTON, 100);
    wait(hold_time2);
    set_val(FIRE_BUTTON, 0);
    wait(rest_time2);
    set_val(FIRE_BUTTON, 0);
}

combo RapidFire3 {
    set_val(FIRE_BUTTON, 100);
    wait(hold_time3);
    set_val(FIRE_BUTTON, 0);
    wait(rest_time3);
    set_val(FIRE_BUTTON, 0);
}

combo RapidFire4 {
    set_val(FIRE_BUTTON, 100);
    wait(hold_time4);
    set_val(FIRE_BUTTON, 0);
    wait(rest_time4);
    set_val(FIRE_BUTTON, 0);
}

combo SPAM_LT {
    set_val(XB1_LT, 100);
    wait(200);
    set_val(XB1_LT, 0);
    wait(25);
}

combo AllowReloading {
    set_val(XB1_LS, 0);
    wait(R_wait);
}

combo AllowSwitching {
    set_val(XB1_LS, 0);
    wait(Y_wait);
}

combo AutoSprint {
    set_val(XB1_LS, 100);
    wait(40);
    set_val(XB1_LS, 0);
    wait(40);
}

combo Prone {
    set_val(XB1_LX, 0);
    set_val(XB1_LY, 0);
    wait(50);
    set_val(XB1_LX, 0);
    set_val(XB1_LY, 0);
    set_val(DROP_BUTTON, 100);
    wait(380);
    prone_flag = TRUE;
}

combo Stand {
    set_val(DROP_BUTTON, 100);
    wait(380);
    prone_flag = FALSE;
}

combo RumbleNotifier {
    set_rumble(RUMBLE_A, 100);
    wait(200);
    reset_rumble();
}

combo LeftLean {
    set_val(XB1_LS, 100);
}

combo RightLean {
    set_val(XB1_RS, 100);
}

 combo Vault_Rappel {
    set_val(XB1_A, 100);
}

 combo Drop_Stand {
    set_val(XB1_B, 100);
}

combo AntiRecoil {
    if(get_val(XB1_RT)) {
    anti_recoil = get_val(10) + ANTI_RECOIL;
    if(anti_recoil > 100) anti_recoil = 100;
    set_val(10, anti_recoil);
    anti_recoil_left = get_val(9) -ANTI_RECOIL_LEFT;
    if(anti_recoil_left > 100) anti_recoil_left = 100;
    set_val(9, anti_recoil_left);
    anti_recoil_right = get_val(9) +ANTI_RECOIL_RIGHT;
    if(anti_recoil_right > 100) anti_recoil_right = 100;
    set_val(9, anti_recoil_right);}
   
    }

combo AntiRecoilADV {
    if(ar_fire && !get_val(FIRE_BUTTON)) {
        ar_tmp = get_val(GAME_Y_AIM) + ANTI_RECOIL_FORCE;
        if(ar_tmp > 100) ar_tmp = 100;
        else if(ar_tmp < -100) ar_tmp = -100;
        set_val(GAME_Y_AIM, ar_tmp); }
}

combo AntiRecoilADV2 {
    if(ar_fire && !get_val(FIRE_BUTTON)) {
        ar_tmp = get_val(GAME_Y_AIM) + ANTI_RECOIL_FORCE2;
        if(ar_tmp > 100) ar_tmp = 100;
        else if(ar_tmp < -100) ar_tmp = -100;
        set_val(GAME_Y_AIM, ar_tmp); }
}





Not as you wanted for turning things on/off because I pretty much had things going. Once you paste script and scroll you'll see how things are turned on and off.

[bonefisher]

This was made to use with Elite or Regular controllers so don't worry about seeing paddles on there. Also haven't got into dialing in on the burst but you can adjust how you like.

[Squidward]

This was made to use with Elite or Regular controllers so don't worry about seeing paddles on there. Also haven't got into dialing in on the burst but you can adjust how you like.

Awesome! You rock! I'll give it a go tonight and let you know how it goes.

[bonefisher]

OK! let me know how it turn out.