(REOLVED) set up question

[Dave R]

so far I've gotten the firmware update max aim downloaded ,battlefield 4 special tactics in memory slot ,goal is to get mouse and belkin n52 workin though xim4 ,whats the next step ?,youtube got me this far ,thanks

[J2Kbr]

Alright, when using MaxAim for Keyboard and Mouse, it is not possible run a Gamepack. However, you can have a custom script loaded on the MaxAim to do any MODs available on the Gamepack. For battlefield 4 this is the script I personally use:

Code: Select all


// Buttons definitions, can be changed to make the script
// compatible with any console or button layout.

define ADS_BUTTON       = PS3_L2;
define SHOOT_BUTTON     = PS3_R2;
define SPOT_BUTTON      = PS4_R1;
define ANALOG_RX        = PS4_RX;
define ANALOG_RY        = PS4_RY;
define ANALOG_LX        = PS4_LX;
define ANALOG_LY        = PS4_LY;

// This setting caps the mouse maximum value send to the console.
define MCAP             = 95;

// The default is 100
// Going over 100 will increase ADS sensitivity
// Going below 100 will decrease ADS sensitivity
define SENS_ADS = 80;

// Control variables
int autospot = 0;
int autofire = 0;

init {
    // Disable the rumble, as we are using the K&M.
    block_rumble();
}

main {
    // if CEMU_EXTRA3 is being pressed (Left Shift)
    if(get_val(CEMU_EXTRA3)) {
        // Swap the analog sticks. Good to turn the tank turret faster,
        // without need swipe the mouse many times.
        swap(ANALOG_RX, ANALOG_LX);
        swap(ANALOG_RY, ANALOG_LY);
    } else {
        // Apply the mouse maximum value cap
        if(get_val(ANALOG_RX) >  MCAP) set_val(ANALOG_RX,  MCAP);
        if(get_val(ANALOG_RX) < -MCAP) set_val(ANALOG_RX, -MCAP);
        if(get_val(ANALOG_RY) >  MCAP) set_val(ANALOG_RY,  MCAP);
        if(get_val(ANALOG_RY) < -MCAP) set_val(ANALOG_RY, -MCAP);
        if(get_val(ADS_BUTTON)) {       
            sensitivity(ANALOG_RX, NOT_USE, SENS_ADS);
            sensitivity(ANALOG_RY, NOT_USE, SENS_ADS);
            deadzone(ANALOG_RX, ANALOG_RY, 4, 4);
        }
    }

    // Auto Fire (aka rapidfire)
   
    // Key '`' disables all rapidfire
    if(event_press(CEMU_EXTRA4)) {
        autofire = 0;
    // Key '1' enables rapidfire mode 1
    } else if(event_press(CEMU_EXTRA5)) {
        autofire = 1;
    // Key '2' enables rapidfire mode 2
    } else if(event_press(CEMU_EXTRA6)) {
        autofire = 2;
    // Key '3' enables rapidfire mode 3
    } else if(event_press(CEMU_EXTRA8)) {
        autofire = 3;
    // Key '4' enables rapidfire mode 4
    } else if(event_press(CEMU_EXTRA9)) {
        autofire = 4;
    }

    // If fire buttons is being pressed
    if(get_val(SHOOT_BUTTON)) {
        // Run the enabled rapidfire combo
        if(autofire == 1) {
            combo_run(AutoFire1);
        } else if(autofire == 2) {
            if(get_val(ADS_BUTTON)) combo_run(AutoFire2);
        } else if(autofire == 3) {
            if(get_val(ADS_BUTTON)) combo_run(AutoFire3);
        } else if(autofire == 4) {
            if(get_val(ADS_BUTTON)) combo_run(AutoFire4);
        }
    } else {
        // stop all rapidfire combos
        combo_stop(AutoFire1);
        combo_stop(AutoFire2);
        combo_stop(AutoFire3);
        combo_stop(AutoFire4);
    }

    // Shows in the TRACE_1 field what is the enabled radpifire
    set_val(TRACE_1, autofire);

    // Auto Spot
    if(event_press(CEMU_EXTRA1)) { if(autospot == 1) autospot = 0; else autospot = 1; }
    if(event_press(CEMU_EXTRA2)) autospot = 2;
    if((autospot == 1 && !get_val(SPOT_BUTTON)) || (autospot == 2 && get_val(ADS_BUTTON))) combo_run(AutoSpot);
    else if(combo_running(AutoSpot)) combo_stop(AutoSpot);
}

combo AutoFire1 {
    set_val(SHOOT_BUTTON, 100);
    wait(40);
    set_val(SHOOT_BUTTON, 0);
    wait(40);
    set_val(SHOOT_BUTTON, 0);
}

combo AutoFire2 {
    set_val(SHOOT_BUTTON, 100);
    wait(40);
    set_val(SHOOT_BUTTON, 0);
    wait(120);
    set_val(SHOOT_BUTTON, 0);
}

combo AutoFire3 {
    set_val(SHOOT_BUTTON, 100);
    wait(40);
    set_val(SHOOT_BUTTON, 0);
    wait(150);
    set_val(SHOOT_BUTTON, 0);
}

combo AutoFire4 {
    set_val(SHOOT_BUTTON, 100);
    wait(40);
    set_val(SHOOT_BUTTON, 0);
    wait(170);
    set_val(SHOOT_BUTTON, 0);
}

combo AutoSpot {
    set_val(SPOT_BUTTON, 100);
    wait(40); wait(1000);
}


[Dave R]

Alright, when using MaxAim for Keyboard and Mouse, it is not possible run a Gamepack. However, you can have a custom script loaded on the MaxAim to do any MODs available on the Gamepack. For battlefield 4 this is the script I personally use:

" it is not possible run a Gamepack " ok so that's good info ,where do I copy and paste this scrip to ? also is there a full video explaining how to get to the outcome I want ?

[Dave R]

so everything hooked up i'm playin bf4 but its passing through T! shows zero or 1 when i push its button what this all mean ?

[bonefisher]

so everything hooked up i'm playin bf4 but its passing through T! shows zero or 1 when i push its button what this all mean ?

0 means you connected correctly and 1 means slot 1 where your script is loaded.

[Dave R]

so Deagle has no reciol now,DMR rapid fires most guns still have recoil

[Dave R]

PKP LMG has zero recoil YAY!, AEK 971 sill recoils