Battlefield (Quick & The Dead)

Adjustable Primary and Secondary Quick Fires! Adjustable Burst Primary Fire! Adjustable Anti-Recoil! New Quick/ Drag/ Hard Scope with Fire Cancel! Info inside. Enjoy!
Version1.0
Authorbonefisher
Publish DateMon, 6 Jun 2016 - 13:41
Last UpdateMon, 6 Jun 2016 - 13:41
Downloads500
RATE


0

0

Code: Select all
 //          This was only designed for BATTLEFIELD 4 OR HARDLINE!
/*******************************************************************************
*  MODS             WORKS FOR PS4 and XBOX ONE CONSOLES             RUMBLE     *
* TURNING                         ON/OFF                            NOTICE     *
* PRIMARY NOTHING ON   HOLD LEFT_GADGET AND CLICK JUMP             NO RUMBLE   *
* QUICK FIRE PRIMARY   HOLD LEFT_GADGET AND CLICK JUMP              1 time     *
* BURST FIRE PRIMARY   HOLD LEFT_GADGET AND CLICK JUMP              2 time     *
* QUICK/DRAG/HARDSCOPE HOLD LEFT_GADGET AND CLICK JUMP              3 time     *
* SECONDARY NOTHING ON HOLD LEFT_GADGET AND CLICK CROUCH           NO RUMBLE   *
* QUICK FIRE SECONDARY HOLD LEFT_GADGET AND CLICK CROUCH            1 time     *
* ANTI-RECOIL  NOT ON  HOLD DOWN_FIRE_MODE AND CLICK JUMP          NO RUMBLE   *
* ANTI-RECOIL HIP& AIM HOLD DOWN_FIRE_MODE AND CLICK JUMP           1 time     *
* ANTI-RECOIL AIM ONLY HOLD DOWN_FIRE_MODE AND CLICK JUMP           2 time     *
* DROP SHOT OFF        HOLD DOWN_FIRE_MODE AND CLICK CROUCH        NO RUMBLE   *
* DROP SHOT ON         HOLD DOWN_FIRE_MODE AND CLICK CROUCH         1 time     *
* AUTO SPRINT OFF      HOLD UP_ACCESSORY AND CLICK JUMP            NO RUMBLE   *
* AUTO SPRINT ON       HOLD UP_ACCESSORY AND CLICK JUMP             1 time     *
* AUTO SPOT OFF        CLICK SPOT                                  NO RUMBLE   *
* AUTO SPOT LT         CLICK SPOT                                   1 time     *
* AUTO SPOT RUN        CLICK SPOT                                   2 time     *
*                                                                              *
*CHOOSE YOUR BUTTON LAYOUT PREFERENCE LEAVE GAME SETTING AT DEFAULT CHANGE HERE*
* DEFAULT SETTING      HOLD BATTLELOG AND CLICK JUMP               NO RUMBLE   *
* FLIPPED DEFAULT      HOLD BATTLELOG AND CLICK JUMP                1 time     *
* BUMPER JUMPER        HOLD BATTLELOG AND CLICK JUMP                2 time     *
* TACTICAL             HOLD BATTLELOG AND CLICK JUMP                3 time     *
*                                                                              *
*           MAKE SURE TO CYCLE THE SWITCHING BEFORE STARTING!!!                *
*                                                                              *
*                SWITCHING BETWEEN PRIMARY AND SECONDARY                       *
* WHEN TAPPING SWITCH_WEAPON YOU WILL GET ONE RUMBLE FOR THE PRIMARY SIDE AND  *
* TWO RUMBLES FOR THE SECONDARY SIDE INCASE YOU GET ON THE WRONG SIDE FOR YOUR *
* CLASS JUST HOLD SWITCH_WEAPON BUTTON FOR 300MS OR LONGER AND RELEASE TO PUT  *
* YOU INLINE WITH WEAPON CLASS. WHEN ADJUSTING FIRE MAKE SURE YOU ARE ON THE   *
* CORRECT SIDE FOR ADJUSTMENTS. WHEN YOU DIE MAKE SURE YOUR BACK ON PRIMARY    *
* SIDE SO SWITCH BEFORE YOU SPAWN.                                             *
*                                                                              *
*                     ADJUSTING QUICK FIRE PRIMARY                             *
* ADJUSTING QUICK FIRE: HOLD FIRE AND CLICK UP_ACCESSORY FOR INCREASING AND    *
* DOWN_FIRE_MODE FOR DECREASING THE FIRE.                                      *
*                    MAKE SURE YOUR ON PRIMARY SIDE!                           *
*                                                                              *
*                     ADJUSTING BURST FIRE PRIMARY                             *
* ADJUSTING BURST FIRE: HOLD AIM AND CLICK UP_ACCESSORY FOR DECREASING SHOTS   *
* AND DOWN_FIRE_MODE FOR INCREASING SHOTS OF FIRE.                             *
* ADJUSTING BURST FIRE: HOLD AIM AND CLICK RIGHT_GADGET FOR DECREASING DELAY   *
* AND LEFT_GADGET FOR INCREASING DELAY OF FIRE.                                *
*                    MAKE SURE YOUR ON PRIMARY SIDE!                           *
*                                                                              *
*                    ADJUSTING QUICK FIRE SECONDARY                            *
* ADJUSTING QUICK FIRE: HOLD FIRE AND CLICK RIGHT_GADGET FOR INCREASING        *
* AND LEFT_GADGET FOR DECREASING THE FIRE.                                     *
*                   MAKE SURE YOUR ON SECONDARY SIDE!                          *
*                                                                              *
*                         ADJUSTING ANTI-RECOIL                                *
*        HOLD JUMP AND CLICK DOWN_FIRE_MODE TO INCREASE PULL DOWN BY 1.        *
*         HOLD JUMP AND CLICK UP_ACCESSORY TO INCREASE UP PULL BY 1.           *
*        HOLD JUMP AND CLICK LEFT_GADGET TO INCREASE PULL TO LEFT BY 1.        *
*       HOLD JUMP AND CLICK RIGHT_GADGET TO INCREASE PULL TO RIGHT BY 1.       *     
*                                                                              *
*                       QUICK/DRAG/HARD SCOPE MOD                              *
* HOLDING AIM AND WHEN RELEASING AIM FIRES THE SHOT ALSO WITH SNIPER BREATH    *
* ENABLED HOLDS IT STEADY. THIS HAS A CANCEL METHOD BUILT IN THE FIRE BUTTON   *
* WHEN AIM IS HELD DOWN AND DON'T WANT TO TAKE SHOT JUST HOLD FIRE DOWN AND    *
* RELEASE AIM WHICH CANCELS THE SHOT. ALSO HELPS IF WANTING TO SAVE SNIPERBEATH*
*                                                                              *
* MAKE SURE TO SHUT OFF AUTO SPOT MOD WHEN YOU ARE IN MENU OR BATTLELOG !      *
*******************************************************************************/

 
define BATTLELOG      =  1;
define MENU           =  2;
define FIRE           =  4;
define AIM            =  7;
define GRENADE        =  6;
define SPOT           =  3;
define UP_ACCESSORY   = 13;
define DOWN_FIRE_MODE = 14;
define LEFT_GADGET    = 15;
define RIGHT_GADGET   = 16;
define SPRINT         =  8;
define MELEE          =  5;
define SWITCH_WEAPON  = 17;
define RELOAD         = 20;
define JUMP           = 19;
define CROUCH         = 18;
 
define ON  = 81;
define OFF = 15;
 
int PrimaryFire, SecondaryFire;
int BurstOfFire, BurstOfFire2;
int AutoRunOnOff;
int RapidFireOnOff;
int HoldTime, RateOfFire;
int HoldTime2, RateOfFire2;
int HoldBurst, ReleaseBurst;
int Primary = FALSE;
int DropShotOnOff;
int AutoSpotOnOff;
int ControllerLayout;
int ToggleAntiRecoil;
int anti_recoil, anti_recoil_left, anti_recoil_right;
int ANTI_RECOIL, ANTI_RECOIL_LEFT, ANTI_RECOIL_RIGHT;
 
init {
    ControllerLayout     = get_pvar(SPVAR_1, 1, 4, 1);
    PrimaryFire          = get_pvar(SPVAR_2, 1, 4, 1);
    SecondaryFire        = get_pvar(SPVAR_3, 1, 2, 2);
    RateOfFire       = get_pvar(SPVAR_4, 25, 250, 62);
    RateOfFire2      = get_pvar(SPVAR_5, 25, 250, 62);
    BurstOfFire    = get_pvar(SPVAR_6, 10, 1000, 300);
    BurstOfFire2    = get_pvar(SPVAR_7, 10, 1000, 50);
    ToggleAntiRecoil     = get_pvar(SPVAR_8, 1, 3, 1);
    ANTI_RECOIL       = get_pvar(SPVAR_9, 0, 100, 30);
    ANTI_RECOIL_LEFT  = get_pvar(SPVAR_10, 0, 100, 2);
    ANTI_RECOIL_RIGHT = get_pvar(SPVAR_11, 0, 100, 0);
    AutoRunOnOff        = get_pvar(SPVAR_12, 1, 2, 1);
    DropShotOnOff       = get_pvar(SPVAR_13, 1, 2, 2);
    AutoSpotOnOff       = get_pvar(SPVAR_14, 1, 3, 1);
}
 
main {
 
    // Set hair triggers
    if (get_val(FIRE)) {set_val(FIRE, ON); }
    if (get_val(AIM))   {set_val(AIM, ON); }
 
    if (get_val(BATTLELOG) && event_press(JUMP)) {
        if (ControllerLayout == 4) {
            ControllerLayout = 1;
            set_pvar(SPVAR_1, ControllerLayout);
        } else if (ControllerLayout == 1) {
            ControllerLayout = 2;
            set_pvar(SPVAR_1, ControllerLayout);
            combo_run(RumbleNotifier);
        } else if (ControllerLayout == 2) {
            ControllerLayout = 3;
            set_pvar(SPVAR_1, ControllerLayout);
            combo_run(DoubleRumbleNotifier);
        } else if (ControllerLayout == 3) {
            ControllerLayout = 4;
            set_pvar(SPVAR_1, ControllerLayout);
            combo_run(TripleRumbleNotifier);
        }
    }
    if(ControllerLayout == 2) {
        swap(SPOT,FIRE); swap(GRENADE,AIM); // FLIPPED DEFAULT BUTTON LAYOUT
    }
    if(ControllerLayout == 3) {
        swap(GRENADE,JUMP);                   // BUMPER JUMPER BUTTON LAYOUT
    }
    if(ControllerLayout == 4) {
        swap(MELEE,CROUCH);                    // TACTICAL BUTTON LAYOUT
    }
 
    if (get_val(LEFT_GADGET) && event_press(JUMP)) {
        if (PrimaryFire == 4) {
            PrimaryFire = 1;
            set_pvar(SPVAR_2, PrimaryFire);
        } else if (PrimaryFire == 1) {
            PrimaryFire = 2;
            set_pvar(SPVAR_2, PrimaryFire);
            combo_run(RumbleNotifier);
        } else if (PrimaryFire == 2) {
            PrimaryFire = 3;
            set_pvar(SPVAR_2, PrimaryFire);
            combo_run(DoubleRumbleNotifier);
        } else if (PrimaryFire == 3) {
            PrimaryFire = 4;
            set_pvar(SPVAR_2, PrimaryFire);
            combo_run(TripleRumbleNotifier);
        }
    }
    if (get_val(LEFT_GADGET) && event_press(CROUCH)) {
        if (SecondaryFire == 1) {
            SecondaryFire = 2;
        } else if (SecondaryFire == 2) {
            SecondaryFire = 1;
        }
        set_pvar(SPVAR_3, SecondaryFire);
 
        if (SecondaryFire == 1) {
            combo_run(RumbleNotifier);
        }
    }
    if(event_release(SWITCH_WEAPON)){
        if(get_ptime(SWITCH_WEAPON) <= 300){
            Primary = !Primary;
        }
        if(Primary){
            set_pvar(SPVAR_2, PrimaryFire);
            combo_run(RumbleNotifier);
            set_pvar(SPVAR_3, SecondaryFire);
        }
        else{
            set_pvar(SPVAR_3, SecondaryFire);
            combo_run(DoubleRumbleNotifier);
        }
    }
    if(PrimaryFire == 2 && get_val(FIRE) && Primary){
        combo_run(RapidFire); combo_stop(AutoSprint);
    }
    if(PrimaryFire == 3 && get_val(FIRE) && Primary){
        combo_run(BurstFire); combo_stop(AutoSprint);
    }
    if(PrimaryFire == 4 && Primary){
    if(get_val(AIM)) { combo_run(SniperBreath);
    }else if (event_release(AIM)) {
        combo_run(SniperFire); combo_stop(SniperBreath);
    }
    if(get_val(FIRE)){ // Cancels fire if held when LT is released.
        combo_stop(SniperFire); combo_stop(SniperBreath);
    } // HOLD RT in so you can save sniper breath and release when needing it.
    if(get_val(FIRE)) set_val(FIRE,0);
    }
 
    if(SecondaryFire == 1 && get_val(FIRE) && !Primary){
        combo_run(RapidFire2); combo_stop(AutoSprint);
    }
 
    if (PrimaryFire == 2 && get_val(FIRE)) {
        if (get_val(UP_ACCESSORY)) {RateOfFire = RateOfFire - 1; }
        if (get_val(DOWN_FIRE_MODE)) {RateOfFire = RateOfFire + 1; }
 
        if (RateOfFire > 250) { RateOfFire = 250; }
        if (RateOfFire < 25) { RateOfFire = 25; }
 
        set_pvar(SPVAR_4, RateOfFire);
        HoldTime = RateOfFire;
        set_val(UP_ACCESSORY, 0); set_val(DOWN_FIRE_MODE, 0);
    }
    if (SecondaryFire == 1 && get_val(FIRE)) {
        if (get_val(RIGHT_GADGET)) {RateOfFire2 = RateOfFire2 - 1; }
        if (get_val(LEFT_GADGET)) {RateOfFire2 = RateOfFire2 + 1; }
 
        if (RateOfFire2 > 250) { RateOfFire2 = 250; }
        if (RateOfFire2 < 25) { RateOfFire2 = 25; }
 
        set_pvar(SPVAR_5, RateOfFire2);
        HoldTime2 = RateOfFire2;
        set_val(RIGHT_GADGET, 0); set_val(LEFT_GADGET, 0);
    }
    if (PrimaryFire == 3 && get_val(AIM) && !get_val(FIRE)) {
        if (get_val(UP_ACCESSORY)) {BurstOfFire = BurstOfFire - 1; }
        if (get_val(DOWN_FIRE_MODE)) {BurstOfFire = BurstOfFire + 1; }
 
        if (BurstOfFire > 1000) { BurstOfFire = 1000; }
        if (BurstOfFire < 10) { BurstOfFire = 10; }
 
        set_pvar(SPVAR_6, BurstOfFire);
        HoldBurst = BurstOfFire;
        set_val(UP_ACCESSORY, 0); set_val(DOWN_FIRE_MODE, 0);
    }
    if (PrimaryFire == 3 && get_val(AIM) && !get_val(FIRE)) {
        if (get_val(RIGHT_GADGET)) {BurstOfFire2 = BurstOfFire2 - 1; }
        if (get_val(LEFT_GADGET)) {BurstOfFire2 = BurstOfFire2 + 1; }
 
        if (BurstOfFire2 > 1000) { BurstOfFire2 = 1000; }
        if (BurstOfFire2 < 10) { BurstOfFire2 = 10; }
 
        set_pvar(SPVAR_7, BurstOfFire2);
        ReleaseBurst = BurstOfFire2;
        set_val(RIGHT_GADGET, 0); set_val(LEFT_GADGET, 0);
    }
    if (get_val(DOWN_FIRE_MODE) && event_press(JUMP)) {                                 
        if (ToggleAntiRecoil == 3) {
            ToggleAntiRecoil = 1;
            set_pvar(SPVAR_8, ToggleAntiRecoil);
        } else if (ToggleAntiRecoil == 1) {
            ToggleAntiRecoil = 2;
            set_pvar(SPVAR_8, ToggleAntiRecoil);
            combo_run(RumbleNotifier);
        } else if (ToggleAntiRecoil == 2) {
            ToggleAntiRecoil = 3;
            set_pvar(SPVAR_8, ToggleAntiRecoil);
            combo_run(DoubleRumbleNotifier);
        }
    }
    if (ToggleAntiRecoil == 2 && get_val(FIRE)) {
        combo_run(AntiRecoil);
    } else if (ToggleAntiRecoil == 3 && get_val(AIM) && get_val(FIRE)) {
        combo_run(AntiRecoil);
    }
    if ((ToggleAntiRecoil == 2 || ToggleAntiRecoil == 3) && get_val(JUMP) && !get_val(AIM) && !get_val(FIRE)) {
        if (event_press(UP_ACCESSORY)) {
            ANTI_RECOIL = ANTI_RECOIL - 1;
 
            if (ANTI_RECOIL < 0) {
                ANTI_RECOIL = 0;
            }
            set_pvar(SPVAR_9, ANTI_RECOIL);
        }
        if (event_press(DOWN_FIRE_MODE)) {
            ANTI_RECOIL = ANTI_RECOIL + 1;
 
            if (ANTI_RECOIL > 100) {
                ANTI_RECOIL = 100;
            }
            set_pvar(SPVAR_9, ANTI_RECOIL);
        }
        if (event_press(LEFT_GADGET)) {
            if (ANTI_RECOIL_RIGHT > 0) {
                ANTI_RECOIL_RIGHT = ANTI_RECOIL_RIGHT - 1;
                ANTI_RECOIL_LEFT = 0;
            } else if (ANTI_RECOIL_RIGHT <= 0 && ANTI_RECOIL_LEFT < 100) {
                ANTI_RECOIL_LEFT = ANTI_RECOIL_LEFT + 1;
                ANTI_RECOIL_RIGHT = 0;
            } else if (ANTI_RECOIL_LEFT >= 100) {
                ANTI_RECOIL_LEFT = 100;
                ANTI_RECOIL_RIGHT = 0;
            }
            set_pvar(SPVAR_10, ANTI_RECOIL_LEFT);
            set_pvar(SPVAR_11, ANTI_RECOIL_RIGHT);
        }
        if (event_press(RIGHT_GADGET)) {
            if (ANTI_RECOIL_LEFT > 0) {
                ANTI_RECOIL_LEFT = ANTI_RECOIL_LEFT - 1;
                ANTI_RECOIL_RIGHT = 0;
            } else if (ANTI_RECOIL_LEFT <= 0 && ANTI_RECOIL_RIGHT < 100) {
                ANTI_RECOIL_RIGHT = ANTI_RECOIL_RIGHT + 1;
                ANTI_RECOIL_LEFT = 0;
            } else if (ANTI_RECOIL_RIGHT >= 100) {
                ANTI_RECOIL_RIGHT = 100;
                ANTI_RECOIL_LEFT = 0;
            }
            set_pvar(SPVAR_10, ANTI_RECOIL_LEFT);
            set_pvar(SPVAR_11, ANTI_RECOIL_RIGHT);
        }
            set_val(UP_ACCESSORY,0);set_val(DOWN_FIRE_MODE,0);
            set_val(LEFT_GADGET,0);set_val(RIGHT_GADGET,0);
    }
    if (get_val(UP_ACCESSORY) && event_press(JUMP)) {
        if (AutoRunOnOff == 1) {
            AutoRunOnOff = 2;
        } else if (AutoRunOnOff == 2) {
            AutoRunOnOff = 1;
        }
        set_pvar(SPVAR_12, AutoRunOnOff);
 
        if (AutoRunOnOff == 1) {
            combo_run(RumbleNotifier);
        }
    }
    if (AutoRunOnOff == 1) {
        if (get_val(12) < -95) { combo_run(AutoSprint);
        }
    }
    if (get_val(DOWN_FIRE_MODE) && event_press(CROUCH)){         
        if (DropShotOnOff == 1) {
            DropShotOnOff = 2;
        } else if (DropShotOnOff == 2) {
            DropShotOnOff = 1;
        }
 
        set_pvar(SPVAR_13, DropShotOnOff);
 
        if (DropShotOnOff == 1) {
            combo_run(RumbleNotifier);
        }
    }
    if (DropShotOnOff == 1) {
        if((!get_val(AIM) && event_press(FIRE)) || (event_release(AIM) && get_val(FIRE))) {
            combo_run(DropShot);
            combo_stop(AutoSprint);
        }
    }
    if (event_press(SPOT)) {                                 
        if (AutoSpotOnOff == 3) {
            AutoSpotOnOff = 1;
            set_pvar(SPVAR_14, AutoSpotOnOff);
        } else if (AutoSpotOnOff == 1) {
            AutoSpotOnOff = 2;
            set_pvar(SPVAR_14, AutoSpotOnOff);
            combo_run(RumbleNotifier);
        } else if (AutoSpotOnOff == 2) {
            AutoSpotOnOff = 3;
            set_pvar(SPVAR_14, AutoSpotOnOff);
            combo_run(DoubleRumbleNotifier);
        }
    }
    if (AutoSpotOnOff == 2 && get_val(7)) {
        combo_run(AutoSpot);
    } else if (AutoSpotOnOff == 3) {
        combo_run(AutoSpot);
    }
}
 
combo    RumbleNotifier      {
    set_rumble(RUMBLE_A, 100);
    wait                (300);
    reset_rumble();
}
combo  DoubleRumbleNotifier  {
    set_rumble(RUMBLE_A, 100);
    wait                (300);
    set_rumble  (RUMBLE_A, 0);
    wait                (300);
    set_rumble(RUMBLE_A, 100);
    wait                (400);
    reset_rumble();
}
combo  TripleRumbleNotifier  {
    set_rumble(RUMBLE_A, 100);
    wait                (300);
    set_rumble  (RUMBLE_A, 0);
    wait                (300);
    set_rumble(RUMBLE_A, 100);
    wait                (400);
    set_rumble  (RUMBLE_A, 0);
    wait                (300);
    set_rumble(RUMBLE_A, 100);
    wait                (400);
    reset_rumble();
}
combo      RapidFire         {
    set_val        (FIRE, ON);
    wait           (HoldTime);
    set_val       (FIRE, OFF);
    wait           (HoldTime);
}
combo      RapidFire2        {
    set_val        (FIRE, ON);
    wait          (HoldTime2);
    set_val       (FIRE, OFF);
    wait          (HoldTime2);
}
combo      BurstFire         {
    set_val        (FIRE, ON);
    wait          (HoldBurst);
    set_val       (FIRE, OFF);
    wait       (ReleaseBurst);
}
combo     SniperBreath       {
    wait                (100);
    set_val     (SPRINT, 100);
    wait               (3500);
    set_val       (SPRINT, 0);
}
combo      SniperFire        {
    set_val        (AIM, 100);
    set_val       (FIRE, 100);
    wait                 (40);
    set_val        (AIM, 100);
    wait                 (40);
}
combo      AutoSprint        {
    set_val      (SPRINT, ON);
    wait                 (40);
    set_val     (SPRINT, OFF);
    wait                 (40);
}
combo      DropShot          {
    set_val     (CROUCH, 100);
    wait                (380);
}
combo      AutoSpot          {
    set_val       (SPOT, 100);
    wait                 (50);
    set_val         (SPOT, 0);
    wait                (980);
}
combo AntiRecoil {
    anti_recoil = get_val(10) + ANTI_RECOIL;
    if(anti_recoil > 100) {
        anti_recoil = 100;
    }
    set_val(10, anti_recoil);
 
    anti_recoil_left = get_val(9) - ANTI_RECOIL_LEFT;
    if(anti_recoil_left < -100) {
        anti_recoil_left = -100;
    }
    set_val(9, anti_recoil_left);
 
    anti_recoil_right = get_val(9) + ANTI_RECOIL_RIGHT;
    if(anti_recoil_right > 100) {
        anti_recoil_right = 100;
    }
    set_val(9, anti_recoil_right);
}