Gran Turismo 5

How about enable slow motion to a perfect driving? Press L3 to activate slow motion. This script also includes combos to automatically start racing in B-Spec mode (D-Pad Right) and to automatically play on A-Spec in the Indianapolis track (D-Pad Up).
Versionv1.00
AuthorConsoleTuner
Publish DateSun, 19 Jun 2011 - 21:17
Last UpdateSun, 19 Jun 2011 - 21:17
Downloads376
RATE

1
0
Code: Select all
/* ************************************************************* *
 *  GRAN TURISMO 5                                               *
 * ************************************************************* */
 
define BS_AUTOPACE = 1;
define BS_AUTORACE = 2;
 
int slow = FALSE;
int lockBack = FALSE;
int autoplayAS = FALSE;
int autoplayBS = FALSE;
 
init {
    block_rumble();
}
 
main {
    // Steering Sensitivity
    if(abs(get_val(PS3_LX)) < 20) set_val(PS3_LX, 0);
 
    // Gas/Break Sensitivity
    if(get_val(PS3_L2)) set_val(PS3_R2, 0);
    sensitivity(PS3_R2, 1, NOT_USE, NOT_USE, 0, 100);
 
    // Slow Motion Control
    if(event_press(PS3_L3)) slow = !slow;
    if(slow && !get_val(PS3_R3)) combo_run(SlowMotion);
 
    // A-Spec: Auto Play
    if(event_press(PS3_UP)) {
        set_led(LED_1, 0);
        set_led(LED_2, 2);
        set_led(LED_3, 0);
        set_led(LED_4, 0);
        autoplayAS = TRUE;
        autoplayBS = FALSE;
        combo_stop(BSpec_Pace);
        combo_stop(BSpec_Race);
        combo_stop(ASpec_Race);
        combo_stop(ASpec_PushRight);
    }
    if(autoplayAS) {
        set_val(PS3_R2, 100);
        combo_run(ASpec_Race);
        combo_run(ASpec_PushRight);
    }
 
    // B-Spec: Auto Play
    if(event_press(PS3_LEFT)) {
        set_led(LED_1, 0);
        set_led(LED_2, 0);
        set_led(LED_3, 2);
        set_led(LED_4, 0);
        autoplayAS = FALSE;
        autoplayBS = BS_AUTOPACE;
        combo_stop(BSpec_Pace);
        combo_stop(BSpec_Race);
        combo_stop(ASpec_Race);
        combo_stop(ASpec_PushRight);
    } else if(event_press(PS3_RIGHT)) {
        set_led(LED_1, 0);
        set_led(LED_2, 0);
        set_led(LED_3, 0);
        set_led(LED_4, 2);
        autoplayAS = FALSE;
        autoplayBS = BS_AUTORACE;
        combo_stop(BSpec_Pace);
        combo_stop(BSpec_Race);
        combo_stop(ASpec_Race);
        combo_stop(ASpec_PushRight);
    }
    if(autoplayBS == BS_AUTOPACE) combo_run(BSpec_Pace);
    else if(autoplayBS == BS_AUTORACE) combo_run(BSpec_Race);
 
    // Disable Auto Play
    if(event_release(PS3_DOWN)) {
        reset_leds();
        autoplayAS = FALSE;
        autoplayBS = FALSE;
        combo_stop(BSpec_Pace);
        combo_stop(BSpec_Race);
        combo_stop(ASpec_Race);
        combo_stop(ASpec_PushRight);
    }
 
    // Lock Look Back
    if(event_release(PS3_L1)) {
        if(get_ptime(PS3_L1) >= 4000) lockBack = TRUE;
        else lockBack = FALSE;
    }
    if(lockBack) set_val(PS3_L1, 100);
 
    // Clear D-Pad
    set_val(PS3_UP, 0);
    set_val(PS3_DOWN, 0);
    set_val(PS3_LEFT, 0);
    set_val(PS3_RIGHT, 0);
}
 
combo SlowMotion {
    set_val(PS3_START, 100);
    wait(40);
    set_val(PS3_START, 0);
}
 
combo ASpec_Race {
    set_val(PS3_CROSS, 100);
    wait(100);
    wait(1000);
}
 
combo ASpec_PushRight {
    set_val(PS3_LX, 30);
    wait(150);
    wait(1000);
}
 
combo BSpec_Race {
    set_val(PS3_CROSS, 100); wait(40); wait(160);
    set_val(PS3_CIRCLE, 100); wait(40);
    wait(4000); wait(4000);
}
 
combo BSpec_Pace {
    set_val(PS3_CROSS, 100); wait(40); wait(160);
    set_val(PS3_CROSS, 100); wait(40);
    wait(4000); wait(4000); wait(4000); wait(4000);
    wait(4000); wait(4000); wait(4000); wait(2000); // 30s
}