/*
Monster Hunter World: Auto Fishing
 
 
Enable/Disable script with Hold L1 + tap Share button.
 
 
Important Notes (Please Read): 
================================
1. Controller vibration MUST be ENABLED.
    Vibration will be reduced to almost none when script is activated.
2. Share button output will be blocked when activating script
3. LED will change to white when script is ON.
 
 
Instructions
================================
1. Cast the fishing rod
2. Hold L1 + tap Share button to ENABLE (and also to DISABLE after you're done)
3. When a fish is detected (via vibration/rumble) the script will pull it in and
    re-cast the fishing rod.
 
 
Tips
================================
1. If there are no more fish in the water, turn the camera around and walk away.
    When you come back the fish are usually respawned.
2. Might want to bring a Ghillie Mantle to hide from monsters if you plan on
    going semi-afk.
 
 
________________________________________________________________________________
 
 
Update Notes (Version 2)
================================
Changes:
1. Script is now activated with Holding L1 + Share button press
 
Added:
1. LED color is white when script is activated.
2. The controller does not vibrate as much anymore when script is activated.
 
*/
 
int isOn = 0;
 
 
main 
{
    // Script activator
    if(get_val(PS4_L1) == 100 && event_press(PS4_SHARE))
    {
        isOn = !isOn;
 
        // LED 
        if(isOn) // White LED when ON
        {
            set_led(LED_1, 1); set_led(LED_2, 1); set_led(LED_3, 1); 
        }
        else // Original LED when OFF
        {
            reset_leds()
        }
    }
 
 
    // Fish detection and rumble reducer
    if(isOn) 
    {
        if(get_rumble(RUMBLE_A) > 0)
        {
            set_rumble(RUMBLE_A, 0);
            combo_run(AutoFish);
        }
        if(get_rumble(RUMBLE_B) > 0 && get_rumble(RUMBLE_A) == 0)
        {
            set_rumble(RUMBLE_B, 0);
        }
    }
 
 
    // PS_SHARE button output blocker when script activated.
    if(get_val(PS4_L1) == 100 && get_val(PS4_SHARE) == 100)
    {
        set_val(PS4_SHARE, 0);
    }
 
}
 
combo AutoFish 
{
    set_val(PS4_CIRCLE, 100)
    wait(100)
    set_val(PS4_CIRCLE, 0)
    wait(3000)
    wait(3000)
    set_val(PS4_R2, 100)
    wait(100)
    set_val(PS4_R2, 0)
}