Jim007 - BF4 Pack

I'll be updating this to add more stuff.
Version0.1
Authorjim007
Publish DateThu, 10 Apr 2014 - 04:26
Last UpdateThu, 10 Apr 2014 - 04:26
Downloads196
RATE


2

0

Code: Select all
define B_ADS = XB1_LT;
define B_GRENADE = XB1_LB;
define B_FIRE = XB1_RT;
define B_SPOT = XB1_RB;
define B_JUMP = XB1_A;
define B_RELOAD = XB1_X;
define B_CROUCH = XB1_B;
define B_SWITCH_WEAPON = XB1_Y;
define B_UP = XB1_UP;
define B_LEFT = XB1_LEFT;
define B_RIGHT = XB1_RIGHT;
define B_DOWN = XB1_DOWN;
define B_SPRINT = XB1_LS;
define B_LY = XB1_LY;
define B_LX = XB1_LX;
define B_RY = XB1_RY;
define B_RX = XB1_RX;
define B_KNIFE = XB1_RS;
define B_BACK = XB1_VIEW;
define B_START = XB1_MENU;
 
/*
    If you want to increase your ADS sensitivity set this to a number over 100.
    If you want to decrease your ADS sensitivity set this to a number below 100.
*/

define SENS_INFANTRY_ADS = 90;
 
 
/*
    If you want to increase your vehicle sensitivity set this to a number over 100.
    If you want to decrease your vehicle sensitivity set this to a number below 100.
*/

define SENS_VEHICLE = 150;
 
// MaxAim Layout Extra Input 1 - Infantry Mode
define KEY_INFANTRY = CEMU_EXTRA1;
 
// MaxAim Layout Extra Input 2 - Vehicle Mode
define KEY_VEHICLE = CEMU_EXTRA2;
 
// MaxAim Layout Extra Input 3 - Toggle Rapid Fire On/Off
// Hold (1 second) to turn it On
// Tap to turn it Off
define KEY_RF = CEMU_EXTRA3;
 
// MaxAim Layout Extra Input 3 - Toggle Auto Spot On/Off
// Hold (1 second) to turn it On
// Tap to turn it Off
define KEY_AS = CEMU_EXTRA4;
 
// RAPID FIRE SETTING: How long (in miliseconds) to hold the fire button
define RF_HOLD = 40;
 
// RAPID FIRE SETTING: How long (in miliseconds) to wait to fire again
define RF_WAIT = 90;
 
int infantry = TRUE;
int vehicle = FALSE;
int auto_fire = FALSE;
int auto_spot = FALSE;
 
main {
 
    if ( infantry )
    {
        if ( get_val(B_ADS) )
        {
            sensitivity(B_RX, NOT_USE, SENS_INFANTRY_ADS);
            sensitivity(B_RY, NOT_USE, SENS_INFANTRY_ADS);
        }
 
        if ( auto_fire && get_val(B_FIRE) )
        {
            combo_run(rapidFire);
        }
        else if (combo_running(rapidFire) )
        {
            combo_stop(rapidFire);
        }
 
        if ( auto_spot && !get_val(B_SPOT) )
        {
            combo_run(autoSpot);
        }
    }
    else // Vehicle Mode
    {
        sensitivity(B_RX, 40, SENS_VEHICLE);
        sensitivity(B_RY, 40, SENS_VEHICLE);
        if ( event_release(B_RELOAD) && get_ptime(B_RELOAD) > 650 )
        {
            infantry = TRUE;
            vehicle = FALSE;
        }
    }
 
    // Configuration Stuff
    if ( event_release(KEY_INFANTRY) )
    {
        infantry = TRUE;
        vehicle = FALSE;
    }
    else if ( event_release(KEY_VEHICLE) )
    {
        infantry = FALSE;
        vehicle = TRUE;
    }
    else if ( event_release(KEY_AS) )
    {
        if ( get_ptime(KEY_AS) > 1000 )
        {
            auto_spot = TRUE;
        }
        else
        {
            auto_spot = FALSE;
        }
    }
    else if ( event_release(KEY_RF) )
    {
        if ( get_ptime(KEY_RF) > 1000 )
        {
            auto_fire = TRUE;
        }
        else
        {
            auto_fire = FALSE;
        }
    }
}//===> END MAIN
 
combo rapidFire {
    set_val(B_FIRE,100);
    wait(RF_HOLD);
    set_val(B_FIRE,0);
    wait(RF_WAIT);
    set_val(B_FIRE,0);
}
 
combo autoSpot {
    set_val(B_SPOT,100);
    wait(40);
    set_val(B_SPOT,0);
    wait(1200);
}