COD Advanced Warfare (AW) v2.2

This is an updated to my version 2.0 script. Version 2.2 adds double jump and refined auto sprint. This one is based upon PS4 and TACTICAL FLIPPED button layout, and it can be easily tailored to meet your console and button layouts. The following MODS can be turned ON/OFF while in game play using the ADS and DPAD buttons: Rapid Fire, Jitter, Auto-Dash and Quick Scope. IMR Quick Reload can be turned on/off with the Rapid Fire. Anti-Recoil & Double Jump can be turned on with R3 and DPAD. Auto Sprint, Drop Shot and Quick Melee can be turned on/off within the script are set to ON by default. The script also includes ADS & SHOOTING button sensitivity increase along with increased look around times. See the script comments for credits. See the forum link “Announcement Topic” for more information.
Version2.2
AuthorUK_Wildcats_Fans
Publish DateFri, 10 Apr 2015 - 16:50
Last UpdateFri, 10 Apr 2015 - 16:50
Downloads800
ForumAnnouncement Topic
RATE


4

0

Release Notes: Please be sure that you review the script especially the comments on Auto Sprint and Reloading. You can tailor this to your specific needs & console. This jitter is for the TAC 19, and you must use GUNG HO with it.
Code: Select all
/*
GPC Online Library
COD Advanced Warfare(AW) Script
=============================================================================
Device:        Titan One
Arthur:        Terry (aka UK_Wildcats_Fans)
Game:          Call of Duty Advanced Warfare
System:        Playstation 4
Controller:    Dualshock 4
Game Settings: Tactial Flipped Button Layout
Website:       www.consoletuner.com
Credit:        Kniightermaare's codaw_simply_devastating_2.gpc & deadeye quickscope; J2Kbr's IMR Quick Reload and Quick Melee; forum members for their help
=============================================================================
CHANGELOG:
Version 1.1: ADS and DPAD are needed to turn mods ON and OFF, removed Superman, Anti-Recoil can be turned ON and OFF
Version 1.2: Added in Quick Melee and IMR Quick Reload from J2Kbr.  IMR quick reload ON/OFF with rapid fire and Quick Melee ON/OFF
Version 1.3: Cleaned up variables, toggle RapidFire when switching weapons (SWAP_WEAPONS)
Version 1.4: Set QuickMelee to always on with time variable for when not in game play, add quick scope and use previous QuickMelee DPAD toggle, set time parameter for IMR Quick Reload to allow getting care packages
Version 1.5: Add AutoSprint with toggle ON/OFF, set Drop Shot to always ON, swap SPRINT_EXO and MELEE, changed the TOGGLE to ADS
Version 1.6: Code clean up, fix bugs and fine tuning of adjustable parameters
Version 1.7: Added IMRQuickReloadON so I could toggle on/off when running the ARX instead of IMR; Added condition to temporarily stop Auto Sprint if RELOAD is pressed
Version 1.8: Set Auto Sprint to always ON; Replace Auto Sprint on DPAD with Jitter for TAC 19; ensure some MODS are off while others are ON.  Commented out TRIANGLE swap weapon section for non-burst play
Version 1.9: Setup for PS4 (take out PS3 LED functions)
Version 2.0: Add in auto dash (left, right, back) and replace anti-recoil with autodash on D PAD.  Fixed issue with dash functions (SPRINT button not working)
Version 2.1: Made adjustments to Auto Sprint to ensure proper reloading
Version 2.2: Added in long press X for double jump
=============================================================================
TOGGLES:
Press ADS in addtion with any of the below.  Using ADS helps to prevent accidental turn ON and OFF when operating killstreaks and/or other times that requires the D PAD
Press LEFT  on the D PAD to activate/deactivate "RAPID FIRE"    LED 4
Press UP    on the D PAD to activate/deactivate "JITTER"        LED 3  [GUNG HO REQUIRED]
Press RIGHT on the D PAD to activate/deactivate "AUTO-DASH"     LED 2
Press DOWN  on the D PAD to activate/deactivate "QUICK SCOPE"   LED 1
 
Press R3 in addtion with any of the below.  Using R3 helps to prevent accidental turn ON and OFF when operating killstreaks and/or other times that requires the D PAD
Press RIGHT on the D PAD to activate/deactivate "ANTI-RECOIL" 
Press UP on the D PAD to activate/deactivate "DOUBLE JUMP" 
=============================================================================
GAMEPLAY COMMENTS
 
My Favorites: Drop Shot, Auto Sprint, Double Jump, Quick Melee
 
Auto Sprint & Reloading: 
Reload times vary with weapons and auto sprint can cause problems.  You sometimes have to let off the joystick, hold the RELOAD button or hold ADS to reload fully
You can adjust the wait times in the reloading combo to add more time if needed to all for full reload. 
 
Double Jump:
You must hold the JUMP button to get the double jump. 
You can play with the wait time in the combo to adjust if necessary to your liking.
 
Anti-Recoil:
There is no one right value.  See this thread for more information.  http://www.consoletuner.com/forum/viewtopic.php?f=17&t=1155
 
Auto Dash:
This can be very helpful, but I have found that it interferes more than helps. Give it a try yourself to see if you like it or not.
 
Quick Scoping:
There are variables to play around with to meet your specific needs.
I am absolutely terrible at quick scoping, so I don't really use this and haven't tested it that much.
=============================================================================
DEFINES
*/

define ADS                       = PS4_L1;          // R1 & L1 can be changed to R2 AND L2
define EXO                       = PS4_L2;          // R1 & L1 can be changed to R2 AND L2
define SPRINT_EXO                = PS4_L3;
define LX                        = PS4_LX;
define LY                        = PS4_LY;
define SHOOT                     = PS4_R1;          // R1 & L1 can be changed to R2 AND L2
define GRENADE                   = PS4_R2;          // R1 & L1 can be changed to R2 AND L2
define CROUCH                    = PS4_R3;          // "Default" button layout is PS4_CIRCLE
define RX                        = PS4_RX;
define RY                        = PS4_RY;
define JUMP                      = PS4_CROSS;
define RELOAD                    = PS4_SQUARE;
define MELEE                     = PS4_CIRCLE;      // "Default" button layout is PS4_R3
define SWAP_WEAPONS              = PS4_TRIANGLE;
define UP                        = PS4_UP;
define DOWN                      = PS4_DOWN;
define LEFT                      = PS4_LEFT;
define RIGHT                     = PS4_RIGHT;
 
define INSTA_FIRE                = 95;   // The % at which it boosts the SHOOT button when pressed - i.e. 95% means when pressed 5%
define INSTA_AIM                 = 95;   // The % at which it boosts the ADS button when pressed - i.e. 95% means when pressed 5%
define INSTA_OTHER               = 95;   // The % at which it boosts the other button when pressed - i.e. 95% means when pressed 5%
define DROPSHOT_QUICKNESS        = 95;   // The % at which it boosts the CROUCH button when pressed - i.e. 95% means when pressed 5%     
define ADS_SPEED                 = 20;   // The % at which it boosts your aiming speed when using ADS         
define RATE_OF_FIRE              = 50;   // Range: 1 to 50 RPS (rounds per second), this varies for each weapon and configuration (i.e type, variant, attachments)
define DISABLE_WITH_SCOPE        = TRUE; // Will not drop shot if ADS is on
define ANTI_RECOIL               = 20;   // Change this value to compensate to the vertical recoil  ASM1 with rapidfire = 40, BAL no grip = 20; Bal with grp = 0;
define ANTI_RECOIL_LEFT          = 0;    // Change this value to compensate to the left
define ANTI_RECOIL_RIGHT         = 0;    // Change this value to compensate to the right
define ONLY_WITH_SCOPE           = TRUE; // Anti-recoil will only be applied with ADS
define DASH_WAIT1                = 350// Auto-dash first wait duration.  This may differ between systems (i.e. PS3, PS4, Xbox 360, XB1)
define DASH_WAIT2                = 80;   // Auto-dash first wait duration.  This may differ between systems (i.e. PS3, PS4, Xbox 360, XB1)
define QUICK_SCOPE_WAIT          = 500// Increase this time for a longer ADS time.  Decrease this time for a shorter ADS time
define RELOAD_WAIT1              = 160// Reload combo wait 1. 
define RELOAD_WAIT2              = 2000; // Reload combo wait 2.  Adjust for more or less to allow for full reload
 
// VARIABLES =============================================================================
 
int DoubleJumpON                 = TRUE;
int AutoSprintON                 = TRUE// Always turned on now
int AutoDashON                   = FALSE;
int QuickMelee_ON                = TRUE// Always turned on now
int RapidFireON                  = FALSE
int DropShotON                   = TRUE// Always turned on now
int InversionON                  = TRUE// Set this to FALSE if not using look inversion enabled in the game setting.  Most people are NOT using look inversion
int JitterON                     = FALSE;
int AntiRecoilON                 = FALSE;
int QuickScopeON                 = FALSE;
int IMRQuickReloadON             = TRUE// RapidFireON and IMRQuickReloadON must be TRUE for IMR quick reload, FALSE when playing with ARX or other burst             
int HoldTime;
int RestTime;
int anti_recoil;
int anti_recoil_left;
int anti_recoil_right;
 
init {
    HoldTime = 500 / RATE_OF_FIRE;
    RestTime = HoldTime - 20;
    if(RestTime < 0) RestTime = 0;
}
 
// MAIN SCRIPT =============================================================================
 
main {   
 
//    swap(SPRINT_EXO, MELEE); // Swapping L3 and CIRCLE for personal game play -- with Tactical button layout, a quicker melee was needed but still prefer crouch for normal play with R3
 
    if(get_val(CROUCH)){sensitivity(CROUCH, NOT_USE, 100 + DROPSHOT_QUICKNESS);} // Allows for quicker crouch if barely pressed       
 
    if(event_press(LEFT) && get_val(ADS)) {  // Turn ON and OFF Rapid Fire and IMR Quick Reload
        RapidFireON = !RapidFireON;
        if(RapidFireON) {
//             set_led(LED_4, 2);
             JitterON = FALSE;               // Turn OFF Jitter if using Rapid Fire
//             set_led(LED_3, 0);
             QuickScopeON = FALSE;           // Turn OFF QuickScope if using Rapid Fire
//             set_led(LED_1, 0);
        }
        else set_led(LED_4, 0);
    }
 
/* Commenting this out while using full auto
    if(event_press(SWAP_WEAPONS)) {          // Turn ON and OFF Rapid Fire and IMR Quick Reload using SWAP_WEAPONS - i.e. burst weapon as primary and full auto as secondary weapon
        RapidFireON = !RapidFireON;
        if(RapidFireON) {
             set_led(LED_4, 2);
             JitterON = FALSE;               // Turn OFF Jitter if using Rapid Fire
             set_led(LED_3, 0);
             QuickScopeON = FALSE;           // Turn OFF QuickScope if using Rapid Fire
             set_led(LED_1, 0);}
        else set_led(LED_4, 0);
    }
*/

 
    if(event_press(UP) && get_val(ADS)) {    // Turns ON and OFF Drop shot
        JitterON = !JitterON;
        if(JitterON) {
//           set_led(LED_3, 2);
           RapidFireON = FALSE;              // Turn OFF Rapid Fire if using Jitter
//           set_led(LED_4, 0);
           AntiRecoilON = FALSE;             // Turn OFF Anti Recoil if using Jitter
//           set_led(LED_2, 0);
           QuickScopeON = FALSE;             // Turn OFF QuickScope if using Jitter
//           set_led(LED_1, 0);
        }
        else set_led(LED_3, 0);
    }
 
    if(event_press(RIGHT) && get_val(ADS)) { // Turns ON and OFF Auto-Dash
        AutoDashON = !AutoDashON;
//        if(AutoDashON) set_led(LED_2, 2);
//        else set_led(LED_2, 0);
    }
 
    if(event_press(RIGHT) && get_val(CROUCH)) { // Turns ON and OFF Anti-Recoil
        AntiRecoilON = !AntiRecoilON;
//        if(AntiRecoilON) set_led(LED_2, 2);
//        else set_led(LED_2, 0);
    }
 
    if(event_press(UP) && get_val(CROUCH)) { // Turns ON and OFF Double Jump
        DoubleJumpON = !DoubleJumpON;
    }
 
 
    if(event_press(DOWN) && get_val(ADS)) {  // Turns ON and OFF Quick Scope
        QuickScopeON = !QuickScopeON;
        if(QuickScopeON) {
//           set_led(LED_1, 2);
           JitterON = FALSE;                 // Turn OFF Jitter if using Quick Scope
//           set_led(LED_3, 0);
           RapidFireON = FALSE;              // Turn OFF Rapid Fire if using Quick Scope
//           set_led(LED_4, 0);
           AntiRecoilON = FALSE;             // Turn OFF Anti Recoil if using Quick Scope
//           set_led(LED_2, 0);
        }
        else set_led(LED_1, 0);
    }
 
  // QUICK MELEE  using on/off for testing purposes. Added time variable to see if it helps with the normal "back" when not in actual game play
  if(event_press(MELEE) && QuickMelee_ON && get_ptime(RELOAD) < 250) {combo_restart(QuickMelee);}
 
  // FAST RELOAD IMR -- I am only using RapidFireON for IMR right now, so set ON with rapidfire
  if(event_release(RELOAD) && RapidFireON && IMRQuickReloadON && get_ptime(RELOAD) < 250) {combo_run(FastReloadIMR);set_val(RELOAD,0);} // time variable needed to allow for getting care packages
 
  // Drop Shot
  if(event_press(SHOOT) && DropShotON){
        combo_stop(AutoSprint)
        combo_run(DropShot);
  }
  if(!DISABLE_WITH_SCOPE || get_val(ADS)) {combo_stop(DropShot);}
 
  // Rapid Fire
  if(get_val(SHOOT) && RapidFireON) {combo_run(RapidFire);}
    else if(combo_running(RapidFire)) {combo_stop(RapidFire);}
 
  // Kniightmare's Jitter
  if(get_val(SHOOT) && JitterON) {combo_run(Jitter);}
    else if(combo_running(Jitter)) {combo_stop(Jitter);}
 
  // Faster movement while aiming with ADS
  if(get_val(ADS)){
     sensitivity(RX, NOT_USE, 100 + ADS_SPEED);
     sensitivity(RY, NOT_USE, 100 + ADS_SPEED);
  }                                                       
 
  // Makes the button 100% pressed even if barely pressed - aka more sensitive and quicker reaction
  if(get_val(ADS)){sensitivity(ADS, 10, 100 + INSTA_AIM);}     
  if(get_val(SHOOT)){sensitivity(SHOOT, 10, 100 + INSTA_FIRE);}
  if(get_val(SPRINT_EXO)){sensitivity(SPRINT_EXO, 10, 100 + INSTA_OTHER);}
  if(get_val(GRENADE)){sensitivity(GRENADE, 10, 100 + INSTA_OTHER);}
 
  // Anti-recoil
  if(!ONLY_WITH_SCOPE || get_val(ADS)) {combo_run(AntiRecoil);}
 
  // Quick Scope -- CANNOT ADS (aka regular scope) while using Quick Scope -- for regular ADS you must toggle off QuickScopeON  -- see "Toggles" section at the top of this script
  if(QuickScopeON && event_press(ADS) ) {combo_run(QuickScope);}
 
/*  I tried using this, but the combo Reloading caused too many issues with using SQUARE to cancel kill cam, sprinting, managing characters when typing
  // AutoSprint -- Try different values (i.e. -90, -95); toggle ON/OFF
  // You may want to tweak these if you are using Gung Ho
  if(get_val(LY) < -99 && AutoSprintON && !combo_running(Reloading)) { combo_run(AutoSprint); }
  else if(get_val(LY) > -99 && AutoSprintON) {combo_stop(AutoSprint); } // Reload will also stop
  if(event_press(SHOOT)) {combo_stop(AutoSprint); set_val(SPRINT_EXO, 0);}  // Autosprint stops while shooting.  You can comment this out if using Gung Ho
  if(event_press(RELOAD)) {combo_stop(AutoSprint); combo_run(Reloading)} // Reload will stop auto sprint
*/

 
  // AutoSprint -- Try different values (i.e. -90, -95); toggle ON/OFF
  if(get_val(LY) < -99 && AutoSprintON) { combo_run(AutoSprint); }
  else if((get_val(LY) > -99 && AutoSprintON)) {combo_stop(AutoSprint); } // Reload will also stop
//  else if((get_val(LY) > -99 && AutoSprintON)|| event_press(RELOAD)) { combo_stop(AutoSprint); set_val(SPRINT_EXO,0);} // Reload will also stop
  if(event_press(RELOAD)|| event_press(SHOOT)) {combo_stop(AutoSprint); combo_run(AllowReloading);}
 
 
/*
  // Used for AutoDash testing purposes only
  if(event_press(RIGHT) && AutoDashON){combo_run(DashRight);}
  if(event_press(LEFT)  && AutoDashON){combo_run(DashLeft);}
  if(event_press(DOWN)  && AutoDashON){combo_run(DashBack);}
*/

 
  // AutoDash
  if(get_val(LY) > 99 && AutoDashON) { combo_run(DashBack); } 
  if(get_val(LX) < -99 && AutoDashON) { combo_run(DashLeft); }
  if(get_val(LX) > 99 && AutoDashON) { combo_run(DashRight); }
 
  // Double Jump
  if(event_press(JUMP) && DoubleJumpON) {
       combo_run(DoubleJump);
  } else if(!get_val(JUMP)) {   // Holding JUMP will let the combo run, and a quick press will work like a normal JUMP or select
       combo_stop(DoubleJump);
  }
 
} // End of MAIN
 
// COMBOS =============================================================================
 
combo DoubleJump {
    set_val(JUMP, 100)// 1st jump
    wait(40);
    set_val(JUMP, 0);
    wait(150);           // timing can be adjusted here
    set_val(JUMP, 100)// 2nd jump
    wait(40);
}
 
combo AllowReloading {
    set_val(SPRINT_EXO, 0);
    wait(160); // can adjust to ensure enough time to reload
}
 
// not currently using as it creates problems
combo Reloading {
    set_val(SPRINT_EXO, 0);
    wait(30);
    set_val(RELOAD, 100);
    wait(RELOAD_WAIT1);
    set_val(RELOAD, 0);
    wait(RELOAD_WAIT2); // can adjust to ensure enough time to reload
}
 
combo RapidFire {
    set_val(SHOOT, 100);
    wait(HoldTime);
    set_val(SHOOT, 0);
    wait(RestTime);
    set_val(SHOOT, 0);
}
 
combo DropShot {
   set_val(SPRINT_EXO,0);
   wait(15)
   set_val(CROUCH, 100);
   wait(15)
   set_val(CROUCH, 100);
   wait(1200);
}
 
combo Jitter {
    set_val(LY, -100);
    set_val(RELOAD, 100);
    wait(30);
    set_val(LY, -100);
    set_val(SPRINT_EXO, 100);
    wait(30);
    set_val(LY, -100);
    wait(20);
    set_val(LY, -100);
}
 
combo FastReloadIMR {
    set_val(RELOAD, 100);
    wait(40);
    set_val(RELOAD, 0);
    wait(1250); // << Adjustable timing; good values test are: 1250.  Lower than this, the quick reload will not work
    set_val(RELOAD, 0);
    set_val(LX, 0);
    set_val(LY, -100);
    set_val(SPRINT_EXO, 100);
    wait(40);
}
 
combo QuickMelee {
    set_val(MELEE, 100);
    wait(40);
    set_val(MELEE, 0);
    wait(250); // << Adjustable timing -- If too low the melee is stopped too quickly and does not fully hit -- If too long it becomes a normal melee.  300 seems good.  Trying at 250
    set_val(MELEE, 0);
    set_val(LX, 100);
    set_val(LY, 0);
    set_val(SPRINT_EXO, 100);
    wait(40);
}
 
combo QuickScope {
    set_val(ADS, 100);
    wait(QUICK_SCOPE_WAIT)            //Increase this time for a longer ADS time.  Decrease this time for a shorter ADS time.
    set_val(ADS, 0);
    wait(10)
    set_val(SHOOT, 100);
    wait(20)
    set_val(SHOOT, 0);
    wait(60)
    set_val(SHOOT, 0);
}
 
combo AutoSprint {
    set_val(SPRINT_EXO, 100);
    wait(10);
    set_val(SPRINT_EXO, 100)
}
 
combo AntiRecoil {                                           
// Look Inversion Enabled
    if(get_val(SHOOT) && AntiRecoilON && InversionON) { // Using AntiRecoilON toggle for testing and when using multiple weapons
    anti_recoil = get_val(10) - ANTI_RECOIL;            // SUBTRACT anti_recoil when LOOK INVERSION is ENABLED
    if(anti_recoil > 100) anti_recoil = 100;
    set_val(10, anti_recoil);
    anti_recoil_left = get_val(9) - ANTI_RECOIL_LEFT;
    if(anti_recoil_left > 100) anti_recoil_left = 100;
    set_val(9, anti_recoil_left);
    anti_recoil_right = get_val(9) + ANTI_RECOIL_RIGHT;
    if(anti_recoil_right > 100) anti_recoil_right = 100;
    set_val(9, anti_recoil_right);}
// Normal Look Inversion - look inversion disabled
    if(get_val(SHOOT) && AntiRecoilON && !InversionON) { // Using AntiRecoilON toggle for testing and when using multiple weapons
    anti_recoil = get_val(10) + ANTI_RECOIL;             // ADD anti_recoil for normal
    if(anti_recoil > 100) anti_recoil = 100;
    set_val(10, anti_recoil);
    anti_recoil_left = get_val(9) - ANTI_RECOIL_LEFT;
    if(anti_recoil_left > 100) anti_recoil_left = 100;
    set_val(9, anti_recoil_left);
    anti_recoil_right = get_val(9) + ANTI_RECOIL_RIGHT;
    if(anti_recoil_right > 100) anti_recoil_right = 100;
    set_val(9, anti_recoil_right);}
}
 
combo DashRight {
    set_val(LX, 100);
    set_val(SPRINT_EXO, 100);
    wait(DASH_WAIT1);
    set_val(LX, 100);
    set_val(SPRINT_EXO, 0);
    wait(DASH_WAIT2);
    set_val(LX, 100);
    set_val(SPRINT_EXO, 0);
}
 
combo DashLeft {
    set_val(LX, -100);
    set_val(SPRINT_EXO, 100);
    wait(DASH_WAIT1);
    set_val(LX, -100);
    set_val(SPRINT_EXO, 0);
    wait(DASH_WAIT2);
    set_val(LX, -100);
    set_val(SPRINT_EXO, 0);
}
 
combo DashBack {
    set_val(LY, 100);
    set_val(SPRINT_EXO, 100);
    wait(DASH_WAIT1);
    set_val(LY, 100);
    set_val(SPRINT_EXO, 0);
    wait(DASH_WAIT2);
    set_val(LY, 100);
    set_val(SPRINT_EXO, 0);
}
 
combo DodgeNotifier {
    set_rumble(RUMBLE_B, 100);
    wait(200);
    set_rumble(RUMBLE_B, 0);
    wait(4000);
}