So I cant just map buttons to match my keyboard?
4 posts
• Page 1 of 1
So I cant just map buttons to match my keyboard?
I just got this and want to use my mouse and keyboard to play games? So I have to download some pack for any game I want to use? Why cant I just hit the button on the controller then the button on the keyboard I want to use? I want to play toy soldiers warchest and I don't see this pack anywhere. Im thinking about sending this back.
-
pasadenapauly - Staff Sergeant
- Posts: 12
- Joined: Sat Feb 06, 2016 5:57 pm
Re: So I cant just map buttons to match my keyboard?
You can use the Max-Aim plugin to accomplish this, Simply map your keyboard/mouse buttons to the corresponding controller buttons, For your mouse you will need to tweak settings for acceleration and axis shape to get the smooth mouse feel you would have on pc.
"We always start with completing the difficult. It just takes us a little longer to do the impossible."
Console Tuner Support Team®
-
AKHUGHES90 - Major
- Posts: 927
- Joined: Mon Nov 24, 2014 12:19 am
- Location: Springfield, IL USA CST (-6:00)
Re: So I cant just map buttons to match my keyboard?
ok so whats all this scripts stuff? so after I mapped all my buttons on my keyboard and I wanted to add rapid fire to my mouse button id have to add a script? would it cancel out my other settings?
-
pasadenapauly - Staff Sergeant
- Posts: 12
- Joined: Sat Feb 06, 2016 5:57 pm
Re: So I cant just map buttons to match my keyboard?
Correct. To add "MODs" with Maxaim you heed make a custom script (gamepacks does not works with plugins). You Maxaim configuration will remains the same and shouls not be affected by the script.
Here is a example of script I use to play BF4 with MaxAim:
Here is a example of script I use to play BF4 with MaxAim:
- Code: Select all
// Buttons definitions, can be changed to make the script
// compatible with any console or button layout.
define ADS_BUTTON = PS3_L2;
define SHOOT_BUTTON = PS3_R2;
define SPOT_BUTTON = PS4_R1;
define ANALOG_RX = PS4_RX;
define ANALOG_RY = PS4_RY;
define ANALOG_LX = PS4_LX;
define ANALOG_LY = PS4_LY;
// This setting caps the mouse maximum value send to the console.
define MCAP = 95;
// The default is 100
// Going over 100 will increase ADS sensitivity
// Going below 100 will decrease ADS sensitivity
define SENS_ADS = 80;
// Control variables
int autospot = 0;
int autofire = 0;
init {
// Disable the rumble, as we are using the K&M.
block_rumble();
}
main {
// if CEMU_EXTRA3 is being pressed (Left Shift)
if(get_val(CEMU_EXTRA3)) {
// Swap the analog sticks. Good to turn the tank turret faster,
// without need swipe the mouse many times.
swap(ANALOG_RX, ANALOG_LX);
swap(ANALOG_RY, ANALOG_LY);
} else {
// Apply the mouse maximum value cap
if(get_val(ANALOG_RX) > MCAP) set_val(ANALOG_RX, MCAP);
if(get_val(ANALOG_RX) < -MCAP) set_val(ANALOG_RX, -MCAP);
if(get_val(ANALOG_RY) > MCAP) set_val(ANALOG_RY, MCAP);
if(get_val(ANALOG_RY) < -MCAP) set_val(ANALOG_RY, -MCAP);
if(get_val(ADS_BUTTON)) {
sensitivity(ANALOG_RX, NOT_USE, SENS_ADS);
sensitivity(ANALOG_RY, NOT_USE, SENS_ADS);
deadzone(ANALOG_RX, ANALOG_RY, 4, 4);
}
}
// Auto Fire (aka rapidfire)
// Key '`' disables all rapidfire
if(event_press(CEMU_EXTRA4)) {
autofire = 0;
// Key '1' enables rapidfire mode 1
} else if(event_press(CEMU_EXTRA5)) {
autofire = 1;
// Key '2' enables rapidfire mode 2
} else if(event_press(CEMU_EXTRA6)) {
autofire = 2;
// Key '3' enables rapidfire mode 3
} else if(event_press(CEMU_EXTRA8)) {
autofire = 3;
// Key '4' enables rapidfire mode 4
} else if(event_press(CEMU_EXTRA9)) {
autofire = 4;
}
// If fire buttons is being pressed
if(get_val(SHOOT_BUTTON)) {
// Run the enabled rapidfire combo
if(autofire == 1) {
combo_run(AutoFire1);
} else if(autofire == 2) {
if(get_val(ADS_BUTTON)) combo_run(AutoFire2);
} else if(autofire == 3) {
if(get_val(ADS_BUTTON)) combo_run(AutoFire3);
} else if(autofire == 4) {
if(get_val(ADS_BUTTON)) combo_run(AutoFire4);
}
} else {
// stop all rapidfire combos
combo_stop(AutoFire1);
combo_stop(AutoFire2);
combo_stop(AutoFire3);
combo_stop(AutoFire4);
}
// Shows in the TRACE_1 field what is the enabled radpifire
set_val(TRACE_1, autofire);
// Auto Spot
if(event_press(CEMU_EXTRA1)) { if(autospot == 1) autospot = 0; else autospot = 1; }
if(event_press(CEMU_EXTRA2)) autospot = 2;
if((autospot == 1 && !get_val(SPOT_BUTTON)) || (autospot == 2 && get_val(ADS_BUTTON))) combo_run(AutoSpot);
else if(combo_running(AutoSpot)) combo_stop(AutoSpot);
}
combo AutoFire1 {
set_val(SHOOT_BUTTON, 100);
wait(40);
set_val(SHOOT_BUTTON, 0);
wait(40);
set_val(SHOOT_BUTTON, 0);
}
combo AutoFire2 {
set_val(SHOOT_BUTTON, 100);
wait(40);
set_val(SHOOT_BUTTON, 0);
wait(120);
set_val(SHOOT_BUTTON, 0);
}
combo AutoFire3 {
set_val(SHOOT_BUTTON, 100);
wait(40);
set_val(SHOOT_BUTTON, 0);
wait(150);
set_val(SHOOT_BUTTON, 0);
}
combo AutoFire4 {
set_val(SHOOT_BUTTON, 100);
wait(40);
set_val(SHOOT_BUTTON, 0);
wait(170);
set_val(SHOOT_BUTTON, 0);
}
combo AutoSpot {
set_val(SPOT_BUTTON, 100);
wait(40); wait(1000);
}
ConsoleTuner Support Team
-
J2Kbr - General of the Army
- Posts: 20323
- Joined: Tue Mar 18, 2014 1:39 pm
4 posts
• Page 1 of 1
Who is online
Users browsing this forum: No registered users and 123 guests