// GPC Online Library
// call_of_duty_advanced_warfare.gpc
/* =====================================================================================================================
* Game: Call Of Duty: Advanced Warfare
* System: Xbox 360
* Controller: Xbox 360, Xbox One
* Game Settings: Should be normal
* Website: Consoletuner.com
**/
/* ---------------------------------------------------------------------------------------------------------------------
* DEFINES
**/
define AIM_BUTTON = XB360_LT;
define SHOOT_BUTTON = XB360_RT;
define DODGE_SPRINT_BUTTON = XB360_LS;
define RELOAD_BUTTON = XB360_X;
define X_AXIS = XB360_LX;
define Y_AXIS = XB360_LY;
define INITIAL_STATE = FALSE; // FALSE to start with Rapid Fire, Auto Aim & Dodge, TRUE otherwise.
define RATE_OF_FIRE = 18; // Range: 1 to 25 RPS (Round/s).
//
// No need to make changes in the code below.
/* ----------------------------------------------------------------------------------------------------------------------
* VARIABLES
**/
int RapidFire_Is_On = INITIAL_STATE;
int Auto_Aim = INITIAL_STATE;
int Dodge = INITIAL_STATE;
int DbleClick_LT = 0;
int DbleClick_RT = 0;
int hold_time, rest_time;
/* ----------------------------------------------------------------------------------------------------------------------
* INITIALIZATION
**/
init {
hold_time = 500 / RATE_OF_FIRE;
rest_time = hold_time - 20;
if(rest_time < 0) rest_time = 0;
}
/* ----------------------------------------------------------------------------------------------------------------------
* MAIN
**/
main {
// Led indicator for Auto Aim On/Off.
set_led(LED_1, 1);
set_led(LED_3, 0);
// Double click L2 to turn on/off Auto Aim (OPTIMIZED FOR COD GAMES CAMPAIGN MODE ONLY).
if(DbleClick_LT > 0) DbleClick_LT = DbleClick_LT - get_rtime();
if(event_press(AIM_BUTTON) && DbleClick_LT <= 0) {
DbleClick_LT = 300; }
else if(event_press(AIM_BUTTON) && DbleClick_LT > 0) {
Auto_Aim = !Auto_Aim;
}
if(Auto_Aim) {
set_led(LED_1, 0);
set_led(LED_3, 1);
}
if(Auto_Aim && get_val(AIM_BUTTON) && get_ptime(AIM_BUTTON) > 420) {
combo_run(AutoAim);
} else if(combo_running(AutoAim)) {
combo_stop(AutoAim); }
// Holding LT triggers Automatic Breath Hold.
if(abs(get_val(AIM_BUTTON)) >= 5) {
combo_run(AutoHoldBreath); }
// Releasing RT triggers Automatic Reload.
if(event_release(SHOOT_BUTTON)) {
combo_run(AutoReload); }
// AutoSprint
if(get_val(Y_AXIS) < -95) { combo_run(AutoSprint); }
else if(get_val(Y_AXIS) > -95) { combo_stop(AutoSprint); }
// Led indicator for Rapid Fire On/Off.
set_led(LED_1, 1);
set_led(LED_4, 0);
// Double click RT to turn on/off Rapid Fire.
if(DbleClick_RT > 0) DbleClick_RT = DbleClick_RT - get_rtime();
if(event_press(SHOOT_BUTTON) && DbleClick_RT <= 0) {
DbleClick_RT = 300; }
else if(event_press(SHOOT_BUTTON) && DbleClick_RT > 0) {
RapidFire_Is_On = !RapidFire_Is_On;
}
if(RapidFire_Is_On) {
set_led(LED_1, 0);
set_led(LED_4, 1);
}
if(RapidFire_Is_On && get_val(SHOOT_BUTTON) >1) {
combo_run(RapidFire);
} else if(combo_running(RapidFire)) {
combo_stop(RapidFire); }
// Press LS to turn on/off Dodge.
if(event_press(DODGE_SPRINT_BUTTON)) { Dodge = !Dodge; }
if(Dodge && get_val(X_AXIS) > 5) { combo_run(Dash_Right); }
if(Dodge && get_val(X_AXIS) < -5) { combo_run(Dash_Left); }
if(Dodge && get_val(Y_AXIS) > 5) { combo_run(Dash_Back); }
if(Dodge) { combo_run(DodgeNotifier); }
// If Dodge is TRUE and either Aim or Trigger or both buttons are press, Dodge is FALSE to not interfere with regular rumble.
if(combo_running(DodgeNotifier) && get_val(AIM_BUTTON) || get_val(SHOOT_BUTTON)) combo_stop(DodgeNotifier);
//Rumble & led indicator for battery power less than 20%.
if(get_battery() < 2) { set_rumble(RUMBLE_B, 100); }
if(get_battery() < 2) { set_led(LED_4, 2); }
}
/* ----------------------------------------------------------------------------------------------------------------------
* COMBOS
**/
combo AutoAim {
set_val(AIM_BUTTON, 100);
wait(20);
set_val(AIM_BUTTON, 0);
wait(10);
set_val(AIM_BUTTON, 0);
}
combo AutoHoldBreath {
set_val(DODGE_SPRINT_BUTTON, 100);
wait(10);
set_val(DODGE_SPRINT_BUTTON, 100);
}
combo AutoReload {
set_val(RELOAD_BUTTON, 100);
wait(100);
set_val(RELOAD_BUTTON, 0);
}
combo AutoSprint {
set_val(DODGE_SPRINT_BUTTON, 100);
wait(10);
set_val(DODGE_SPRINT_BUTTON, 100);
}
combo RapidFire {
set_val(SHOOT_BUTTON, 100);
wait(hold_time);
set_val(SHOOT_BUTTON, 0);
wait(rest_time);
set_val(SHOOT_BUTTON, 0);
}
combo Dash_Right {
set_val(X_AXIS, 100);
set_val(DODGE_SPRINT_BUTTON, 100);
wait(100);
set_val(X_AXIS, 100);
set_val(DODGE_SPRINT_BUTTON, 0);
wait(80);
set_val(X_AXIS, 100);
set_val(DODGE_SPRINT_BUTTON, 0);
}
combo Dash_Left {
set_val(X_AXIS, -100);
set_val(DODGE_SPRINT_BUTTON, 100);
wait(100);
set_val(X_AXIS, -100);
set_val(DODGE_SPRINT_BUTTON, 0);
wait(80);
set_val(X_AXIS, -100);
set_val(DODGE_SPRINT_BUTTON, 0);
}
combo Dash_Back {
set_val(Y_AXIS, 100);
set_val(DODGE_SPRINT_BUTTON, 100);
wait(100);
set_val(Y_AXIS, 100);
set_val(DODGE_SPRINT_BUTTON, 0);
wait(80);
set_val(Y_AXIS, 100);
set_val(DODGE_SPRINT_BUTTON, 0);
}
combo DodgeNotifier {
set_rumble(RUMBLE_B, 100);
wait(200);
set_rumble(RUMBLE_B, 0);
wait(4000);
}